CODEWITHSUNDEEP
elixirecto
Junaid Farooq
Junaid Farooq

Reputation: 2608

Increasing date with few miliseonds using Enum.reduce Elixir

I have been using Enum.reduce

Enum.reduce(email_array, {[], [], []}, fn email, {shares, share_requests, changes} = _acc ->

end)

I am going to pass a method on each reducer as

CameraActivity.log_activity(caller, camera, "shared", %{with: email, ip: requester_ip}, done_at)

In done_at, the default values are Ecto.DateTime.utc, But I want to increase this date and time on each Enum.reduce.

I have tried to declare the datetime in the very start of Enum.reduce as done_at = Ecto.DateTime.utc, But I have no idea how I am going to loop it in Enum.reduce, so that I may increase few seconds into it.The purpose of this to only change the activity time for each iteration. any help will be appreciated thanks

Update for Dogbert

Enum.reduce(email_array, {[], [], []}, fn email, {shares, share_requests, changes} = _acc ->
  with {:found_user, sharee} <- ensure_user(email)
  do
    case CameraShare.create_share(camera, sharee, caller, params["rights"], params["message"]) do
      {:ok, camera_share} ->
        unless caller == sharee do
          send_email_notification(caller, camera, sharee.email, camera_share.message)
        end
        Camera.invalidate_user(sharee)
        Camera.invalidate_camera(camera)
        CameraActivity.log_activity(caller, camera, "shared", %{with: sharee.email, ip: requester_ip})
        {[camera_share | shares], share_requests, changes}
      {:error, changeset} ->
        {shares, share_requests, [attach_email_to_message(changeset, email) | changes]}
    end
  else
    {:not_found, email} ->
      case CameraShareRequest.create_share_request(camera, email, caller, params["rights"], params["message"]) do
        {:ok, camera_share_request} ->
          send_email_notification(caller, camera, email, camera_share_request.message, camera_share_request.key)
          CameraActivity.log_activity(caller, camera, "shared", %{with: email, ip: requester_ip})
          Intercom.intercom_activity(Application.get_env(:evercam_media, :create_intercom_user), get_user_model(email), get_user_agent(conn), requester_ip, "Shared-Non-Registered")
          {shares, [camera_share_request | share_requests], changes}
        {:error, changeset} ->
          {shares, share_requests, [attach_email_to_message(changeset, email) | changes]}
      end
  end
end)

Upvotes: 0

Views: 110

Answers (1)

Dogbert
Dogbert

Reputation: 222198

You already have 3-tuple as the accumulator in the Enum.reduce/3 call. You can add a datetime value as the 4th item in the tuple and increment it in every iteration. For example, to increment it by 5 seconds, you can do:

Enum.reduce(email_array, {[], [], [], Ecto.DateTime.utc}, fn email, {shares, share_requests, changes, datetime} = _acc ->
  # next_datetime is datetime + 5 seconds
  next_datetime = datetime |>
    Ecto.DateTime.to_erl |>
    :calendar.datetime_to_gregorian_seconds |>
    Kernel.+(5) |>
    :calendar.gregorian_seconds_to_datetime |>
    Ecto.DateTime.from_erl

  # `next_datetime` should be returned as the 4th value of each tuple below.
  # `datetime` can be used as the current value.

  with {:found_user, sharee} <- ensure_user(email)
  do
    case CameraShare.create_share(camera, sharee, caller, params["rights"], params["message"]) do
      {:ok, camera_share} ->
        ...
        {[camera_share | shares], share_requests, changes, next_datetime}
      {:error, changeset} ->
        {shares, share_requests, [attach_email_to_message(changeset, email) | changes], next_datetime}
    end
  else
    {:not_found, email} ->
      case CameraShareRequest.create_share_request(camera, email, caller, params["rights"], params["message"]) do
        {:ok, camera_share_request} ->
          ...
          {shares, [camera_share_request | share_requests], changes, next_datetime}
        {:error, changeset} ->
          {shares, share_requests, [attach_email_to_message(changeset, email) | changes], next_datetime}
      end
  end
end)

Upvotes: 1

Related Questions