gretty appStart fails with unknown property 'classesDirs'

Question

I'm trying to build a Java Servlet with gradle gretty plugin (gradle version 3.4). I have a dependency to another project databaseprovider:1.0-SNAPSHOT (includes connection to the database and some spring definitions...). When I run the task "gradle war" the .war-file is built properly with all dependencies in WEB-INF/lib. But when I try to start with "gradle appStart" I have following problem:

What went wrong: Execution failed for task ':appStart'. Could not get unknown property 'classesDirs' for main classes of type org.gradle.api.internal.tasks.DefaultSourceSetOutput.

Caused by: groovy.lang.MissingPropertyException: Could not get unknown property 'classesDirs' for main classes of type org.gradle.api.internal.tasks.DefaultSourceSetOutput.

Without the dependency databaseprovider:1.0-SNAPSHOT the jetty starts without problems:

INFO Jetty 9.2.22.v20170606 started and listening on port 8080

build.gradle:

buildscript {
  repositories {
    jcenter()
  }

  dependencies {
    classpath "org.akhikhl.gretty:gretty:+"
    classpath "org.springframework.boot:spring-boot-gradle-plugin:1.4.0.RELEASE"
  }
}

apply plugin:'java'
apply plugin: 'eclipse'
apply plugin: 'war'
apply from: 'https://raw.github.com/akhikhl/gretty/master/pluginScripts/gretty.plugin'

repositories {
    maven {
        url "http://..."
    }
    mavenLocal()
}

dependencies {
    compile('databaseprovider:1.0-SNAPSHOT'){
        changing=true
    }
}

gretty {
    httpPort = 8080
    contextPath = '/'
    servletContainer = 'jetty9'    
}

build.gradle from databaseprovider:

buildscript {
    repositories {
      maven {
          url "http://..."
      }
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:1.4.0.RELEASE")
    }
}
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'eclipse'
apply plugin: 'spring-boot'
apply from: 'liquibase.gradle'


jar {
    baseName = 'databaseprovider'
    version =  '1.0-SNAPSHOT'
}

repositories {
    maven {
        url "http://..."
    }
    mavenLocal()
    jcenter()
}

configurations.all {
    resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

dependencies {
    compile("org.springframework.boot:spring-boot-starter-data-jpa:1.4.0.RELEASE")
    compile group: 'org.springframework.data', name: 'spring-data-jpa', version:'1.10.2.RELEASE'
    compile group: 'org.hibernate', name: 'hibernate-c3p0', version: '5.0.9.Final'
    testRuntime group: 'com.h2database', name: 'h2', version: '1.4.192'
    compile group: 'ch.qos.logback', name: 'logback-classic', version:'1.0.13'
    compile group: 'ch.qos.logback', name: 'logback-core', version:'1.0.13'
    compile group: 'org.slf4j', name: 'slf4j-api', version:'1.7.5'
    compile group: 'org.slf4j', name: 'jcl-over-slf4j', version:'1.7.5'
    compile group: 'org.slf4j', name: 'log4j-over-slf4j', version:'1.7.5'
    compile group: 'org.reflections', name: 'reflections', version: '0.9.11'
    compile (group: 'com.mattbertolini', name: 'liquibase-slf4j', version: "1.2.1")
    compile (group: 'org.liquibase', name: 'liquibase-core', version: "3.5.3")
    compile group: 'javax.validation', name: 'validation-api', version: '1.1.0.Final'
    testCompile("junit:junit")
    runtime("mysql:mysql-connector-java:5.1.39")
    testCompile("org.springframework:spring-test")
}

Answer 1

I found this question by googling for the error message when I encountered this issue. For me, I found my answer in this Github thread. Basically, by upgrading my version of Gradle to 4.8 I was able to resolve the issue.

Answer 2

I was able to solve the problem by adding the version of gretty:

After I changed the classpath in build.gradle

classpath "org.akhikhl.gretty:gretty:+"

to

classpath "org.akhikhl.gretty:gretty:1.4.2"

(compatible version to gradle 3.4) jetty starts without exceptions.