CODEWITHSUNDEEP
perlsortinghash
masterial
masterial

Reputation: 2216

How do I sort a hash of hashes by value using Perl?

I have this code

use strict;
use warnings;

my %hash;
$hash{'1'}= {'Make' => 'Toyota','Color' => 'Red',};
$hash{'2'}= {'Make' => 'Ford','Color' => 'Blue',};
$hash{'3'}= {'Make' => 'Honda','Color' => 'Yellow',};

foreach my $key (keys %hash){
  my $a = $hash{$key}{'Make'};
  my $b = $hash{$key}{'Color'};
  print "$a $b\n";
}

And this output:

Toyota Red
Honda Yellow
Ford Blue

How can I sort it by car make?

How do I sort a hash of hashes by value using Perl?

Upvotes: 4

Views: 15873

Answers (3)

Zaid
Zaid

Reputation: 37146

plusplus is right... an array of hashrefs is likely a better choice of data structure. It's more scalable too; add more cars with push:

my @cars = (
             { make => 'Toyota', Color => 'Red'    },
             { make => 'Ford'  , Color => 'Blue'   },
             { make => 'Honda' , Color => 'Yellow' },
           );

foreach my $car ( sort { $a->{make} cmp $b->{make} } @cars ) {

    foreach my $attribute ( keys %{ $car } ) {

        print $attribute, ' : ', $car->{$attribute}, "\n";
    }
}

Upvotes: 3

plusplus
plusplus

Reputation: 2030

#!/usr/bin/perl

use strict;
use warnings;

my %hash = (
    1 => { Make => 'Toyota', Color => 'Red', },
    2 => { Make => 'Ford',   Color => 'Blue', },
    3 => { Make => 'Honda',  Color => 'Yellow', },
);

# if you still need the keys...
foreach my $key (    #
    sort { $hash{$a}->{Make} cmp $hash{$b}->{Make} }    #
    keys %hash
    )
{
    my $value = $hash{$key};
    printf( "%s %s\n", $value->{Make}, $value->{Color} );
}

# if you don't...
foreach my $value (                                     #
    sort { $a->{Make} cmp $b->{Make} }                  #
    values %hash
    )
{
    printf( "%s %s\n", $value->{Make}, $value->{Color} );
}

Upvotes: 10

Colin Fine
Colin Fine

Reputation: 3364

print "$_->{Make} $_->{Color}" for  
   sort {
      $b->{Make} cmp $a->{Make}
       } values %hash;

Upvotes: 3

Related Questions