CODEWITHSUNDEEP
excelvba
Serveira
Serveira

Reputation: 51

VBA - Get cursor position as cell address

I have the following code which works fine for retrieving the cursor position as pixels:

Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
' Create custom variable that holds two integers
Type POINTAPI
    Xcoord As Long
    Ycoord As Long
End Type

Sub GetCursorPosDemo()
    Dim llCoord As POINTAPI
    ' Get the cursor positions
    GetCursorPos llCoord
    ' Display the cursor position coordinates
    MsgBox "X Position: " & llCoord.Xcoord & vbNewLine & "Y Position: " & llCoord.Ycoord
End Sub

I'd like it to return the cell address on which my cursor currently is, or perhaps the coordinates in Points, so I can convert it to an address. Is that possible?

Upvotes: 2

Views: 19242

Answers (1)

cyboashu
cyboashu

Reputation: 10443

Use ActiveWindow.RangeFromPoint to get the cell address.

Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
' Create custom variable that holds two integers
Type POINTAPI
    Xcoord As Long
    Ycoord As Long
End Type

Sub GetCursorPosDemo()
    Dim llCoord As POINTAPI
    Dim rng As Range
    ' Get the cursor positions
    GetCursorPos llCoord
    ' Display the cursor position coordinates
    'MsgBox "X Position: " & llCoord.Xcoord & vbNewLine & "Y Position: " & llCoord.Ycoord

    Set rng = GetRange(llCoord.Xcoord, llCoord.Ycoord)

    If Not rng Is Nothing Then
        MsgBox "Cell under mouse is :" & rng.Address
    Else
        MsgBox "Not a valid location."
    End If

End Sub

Function GetRange(x As Long, y As Long) As Range
    Set GetRange = ActiveWindow.RangeFromPoint(x, y)
End Function

Upvotes: 9

Related Questions