ComboBox as DataGridTemplateColumn SelectedValue not updating bound property

Question

I am having trouble implementing this CustComboBox (renamed MultiColumnComboBox) with a DataGrid popup into a DataGridTemplateColumn: https://www.codeproject.com/Articles/43074/WPF-Custom-ComboBox

Here's a link to SampleApp I threw together to show my current implementation and issues: https://drive.google.com/file/d/1ChZKjeppf-J04j3RGr6k8tPUE2W8oBBc/view?usp=sharing

In the example I have two Objects:

ConnectionPair has 2 string properties "Connection" and "EQConnection"
ToolObj has a string property "ConnectionT"

SampleApp MainWindow.vb:

    Private _ToolObjCollection As New ObservableCollection(Of ToolObj)
    Public Property ToolObjCollection As ObservableCollection(Of ToolObj)
        Get
            Return _ToolObjCollection
        End Get
        Set(value As ObservableCollection(Of ToolObj))
            _ToolObjCollection = value
        End Set
    End Property

    Private _ConnectionPairCollection As New ObservableCollection(Of ConnectionPair)
    Public Property ConnectionPairCollection As ObservableCollection(Of ConnectionPair)
        Get
            Return _ConnectionPairCollection
        End Get
        Set(value As ObservableCollection(Of ConnectionPair))
            _ConnectionPairCollection = value
        End Set
    End Property

    Private _TestTool As New ToolObj("conn2")
        Public Property TestTool As ToolObj
        Get
            Return _TestTool
        End Get
        Set(value As ToolObj)
            _TestTool = value
        End Set
    End Property

    Sub New()
        InitializeComponent()

        _ToolObjCollection.Add(New ToolObj("conn1"))
        _ToolObjCollection.Add(New ToolObj("conn2"))

        _ConnectionPairCollection.Add(New ConnectionPair("conn1", "eqconn1"))
        _ConnectionPairCollection.Add(New ConnectionPair("conn2", "eqconn2"))

        DataContext = Me

    End Sub

I want to bind ItemsSource of the Combo Popup to ConnectionPairCollection, and I want the selection to update the ConnectionT property on my ToolObj.

When doing this with the MultiColumnComboBox outside of a DataGridTemplateColumn, everything seems to work fine. Implementation looks like this:

When I put the MultiColumnComboBox in a DataGridTemplateColumn of a DataGrid with its ItemsSource bound to ToolObjCollection, the binding only works one way. It correctly receives SelectedValue from my ToolObj and registers the proper selection in the popup, but changing the selection of the ComboBox does not update the value of the ToolObj. Implementation looks like this:

I've tried explicitly setting Binding Mode of SelectedValue to TwoWay but it does nothing (as expected, since TwoWay doesn't need to explicitly be set in the first implementation of the MultiColumnCombo)

Is there something I'm missing? Or perhaps some added coding structure I need to add to either Object class or MainWindow codebehind?

For Reference, my ported version of the CustComboBox:

MultiColumnComboBox.vb

' Follow steps 1a or 1b and then 2 to use this custom control in a XAML file.
'
' Step 1a) Using this custom control in a XAML file that exists in the current project.
' Add this XmlNamespace attribute to the root element of the markup file where it is 
' to be used:
'
'     xmlns:MyNamespace="clr-namespace:WinSurvWPF"
'
'
' Step 1b) Using this custom control in a XAML file that exists in a different project.
' Add this XmlNamespace attribute to the root element of the markup file where it is 
' to be used:
'
'     xmlns:MyNamespace="clr-namespace:WinSurvWPF;assembly=WinSurvWPF"
'
' You will also need to add a project reference from the project where the XAML file lives
' to this project and Rebuild to avoid compilation errors:
'
'     Right click on the target project in the Solution Explorer and
'     "Add Reference"->"Projects"->[Browse to and select this project]
'
'
' Step 2)
' Go ahead and use your control in the XAML file. Note that Intellisense in the
' XML editor does not currently work on custom controls and its child elements.
'
'     
'

Imports System.ComponentModel
Imports System.Windows.Markup
Imports System.Collections.ObjectModel
Imports System.Windows.Controls.Primitives
Imports System.Runtime.CompilerServices

''' 
''' 
''' 


Public Class MultiColumnComboBox
    Inherits ComboBox
    Implements INotifyPropertyChanged
    Public Event PropertyChanged As PropertyChangedEventHandler Implements INotifyPropertyChanged.PropertyChanged
    Private Sub NotifyPropertyChanged( Optional ByVal propertyName As String = Nothing)
        RaiseEvent PropertyChanged(Me, New PropertyChangedEventArgs(propertyName))
    End Sub


    Const partPopupDataGrid As String = "PART_PopupDataGrid"
    'Columns of DataGrid
    Private _Columns As ObservableCollection(Of DataGridTextColumn)
    'Attached DataGrid control
    Private PopupDataGrid As DataGrid

    Shared Sub New()
        DefaultStyleKeyProperty.OverrideMetadata(GetType(MultiColumnComboBox), New FrameworkPropertyMetadata(GetType(MultiColumnComboBox)))
    End Sub

    'The property is default and Content property for CustComboBox
    
    Public ReadOnly Property Columns() As ObservableCollection(Of DataGridTextColumn)
        Get
            If Me._Columns Is Nothing Then
                Me._Columns = New ObservableCollection(Of DataGridTextColumn)()
            End If
            Return Me._Columns
        End Get
    End Property

    'Apply theme and attach columns to DataGrid popupo control
    Public Overrides Sub OnApplyTemplate()
        If PopupDataGrid Is Nothing Then

            PopupDataGrid = TryCast(Me.Template.FindName(partPopupDataGrid, Me), DataGrid)
            If PopupDataGrid IsNot Nothing AndAlso _Columns IsNot Nothing Then
                'Add columns to DataGrid columns
                For i As Integer = 0 To _Columns.Count - 1
                    PopupDataGrid.Columns.Add(_Columns(i))
                Next

                'Add event handler for DataGrid popup
                PopupDataGrid.AddHandler(PreviewMouseDownEvent, New MouseButtonEventHandler(AddressOf PopupDataGrid_MouseDown))

                PopupDataGrid.AddHandler(SelectionChangedEvent, New SelectionChangedEventHandler(AddressOf PopupDataGrid_SelectionChanged))
            End If
        End If
        'Call base class method
        MyBase.OnApplyTemplate()
    End Sub

    'Synchronize selection between Combo and DataGrid popup
    Private Sub PopupDataGrid_SelectionChanged(sender As Object, e As SelectionChangedEventArgs)
        'When open in Blend prevent raising exception 
        If Not DesignerProperties.GetIsInDesignMode(Me) Then
            Dim dg As DataGrid = TryCast(sender, DataGrid)
            If dg IsNot Nothing Then
                Me.SelectedItem = dg.SelectedItem
                Me.SelectedValue = dg.SelectedValue
                Me.SelectedIndex = dg.SelectedIndex

                Me.SelectedValuePath = dg.SelectedValuePath
            End If
        End If
    End Sub

    'Event for DataGrid popup MouseDown
    Private Sub PopupDataGrid_MouseDown(sender As Object, e As MouseButtonEventArgs)
        Dim dg As DataGrid = TryCast(sender, DataGrid)
        If dg IsNot Nothing Then
            Dim dep As DependencyObject = DirectCast(e.OriginalSource, DependencyObject)

            ' iteratively traverse the visual tree and stop when dep is one of ..
            While (dep IsNot Nothing) AndAlso Not (TypeOf dep Is DataGridCell) AndAlso Not (TypeOf dep Is DataGridColumnHeader)
                dep = VisualTreeHelper.GetParent(dep)
            End While

            If dep Is Nothing Then
                Return
            End If

            ' do something
            If TypeOf dep Is DataGridColumnHeader Then
            End If
            'When user clicks to DataGrid cell, popup have to be closed
            If TypeOf dep Is DataGridCell Then
                Me.IsDropDownOpen = False
            End If
        End If
    End Sub

    'When selection changed in combobox (pressing  arrow key down or up) must be synchronized with opened DataGrid popup
    Protected Overrides Sub OnSelectionChanged(e As SelectionChangedEventArgs)
        MyBase.OnSelectionChanged(e)
        If PopupDataGrid Is Nothing Then
            Return
        End If

        If Not DesignerProperties.GetIsInDesignMode(Me) Then
            If IsDropDownOpen Then
                PopupDataGrid.SelectedItem = Me.SelectedItem
                If PopupDataGrid.SelectedItem IsNot Nothing Then
                    PopupDataGrid.ScrollIntoView(PopupDataGrid.SelectedItem)
                End If
            End If
        End If
    End Sub
    Protected Overrides Sub OnDropDownOpened(e As EventArgs)
        PopupDataGrid.SelectedItem = Me.SelectedItem

        MyBase.OnDropDownOpened(e)

        If PopupDataGrid.SelectedItem IsNot Nothing Then
            PopupDataGrid.ScrollIntoView(PopupDataGrid.SelectedItem)
        End If

    End Sub
End Class

MultiColumnComboBox Resource Dictionary:


    
    
        
        
        
        
    
    
    M 0 0 L 3.5 4 L 7 0 Z

misterkiem · Accepted Answer

Found a way to get it working, though I'm not sure if it's the most efficient. Either way, I added a dependency property to the MultiColumnComboBox control: BindingPath as String:

Public Shared ReadOnly BindingPathProperty As DependencyProperty =
    DependencyProperty.Register("BindingPath", GetType(String), GetType(MultiColumnComboBox))
Public Property BindingPath As String
    Get
        Return GetValue(BindingPathProperty)
    End Get
    Set(value As String)
        SetValue(BindingPathProperty, value)
    End Set
End Property

Then, I modified the SelectionChanged event handler to check for a set BindingPath value, and set the target property via CallByName:

Private Sub PopupDataGrid_SelectionChanged(sender As Object, e As SelectionChangedEventArgs)
    If Not DesignerProperties.GetIsInDesignMode(Me) Then
        Dim dg As DataGrid = TryCast(sender, DataGrid)
        If dg IsNot Nothing Then
            Me.SelectedItem = dg.SelectedItem
            Me.SelectedValue = dg.SelectedValue
            Me.SelectedIndex = dg.SelectedIndex
            Me.SelectedValuePath = dg.SelectedValuePath

            If BindingPath IsNot Nothing Then
                CallByName(Me.DataContext, BindingPath, CallType.Set, Me.SelectedValue)
            End If
        End If
    End If
End Sub

Now, when setting BindingPath of the MultiColumnCombo to "ConnectionT", everything updates properly when making selections to the nested MultiColumnCombo..

ComboBox as DataGridTemplateColumn SelectedValue not updating bound property

Answers (2)

Related Questions