CODEWITHSUNDEEP
excelvba
Armani
Armani

Reputation: 23

Combine and Append data from multiple Excel workbooks into one worksheet

Below I found a VBA Script online that takes all worksheets from workbooks in a directory, and combines them all in one workbook as separate sheets. However, I don't want them to be separate sheets. I want all data in the sheets to be in a single worksheet.

Sub GetSheets()
    Path = "Desktop\RandoDir"
    Filename = Dir(Path & "\*.csv*")
    Do While Filename <> ""
        Workbooks.Open Filename:=Path & Filename, ReadOnly:=True
        For Each Sheet In ActiveWorkbook.Sheets
            'MsgBox Filename      ---Debugging
            Sheet.Copy After:=ThisWorkbook.Sheets(1)
        Next Sheet
        Workbooks(Filename).Close
        Filename = Dir()
   Loop
End Sub

If I had data structured like this in two files:

   **File1**                **File2**
Header1|Header2    |     Header1|Header2
Tim    |Smith      |     Mike   |Jones

I want the merged worksheet to display

   **File3**
Header1|Header2
Tim    |Smith
Mike   |Jones

Upvotes: 0

Views: 4460

Answers (2)

ASH
ASH

Reputation: 20342

This will do what you want.

Sub Basic_Example_1()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceRcount As Long, Fnum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim rnum As Long, CalcMode As Long

    'Fill in the path\folder where the files are
    MyPath = "C:\Users\Ron\test"

    'Add a slash at the end if the user forget it
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    'If there are no Excel files in the folder exit the sub
    FilesInPath = Dir(MyPath & "*.xl*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    'Fill the array(myFiles)with the list of Excel files in the folder
    Fnum = 0
    Do While FilesInPath <> ""
        Fnum = Fnum + 1
        ReDim Preserve MyFiles(1 To Fnum)
        MyFiles(Fnum) = FilesInPath
        FilesInPath = Dir()
    Loop

    'Change ScreenUpdating, Calculation and EnableEvents
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    'Add a new workbook with one sheet
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    rnum = 1

    'Loop through all files in the array(myFiles)
    If Fnum > 0 Then
        For Fnum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next

                With mybook.Worksheets(1)
                    Set sourceRange = .Range("A1:C1")
                End With

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    'if SourceRange use all columns then skip this file
                    If sourceRange.Columns.Count >= BaseWks.Columns.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceRcount = sourceRange.Rows.Count

                    If rnum + SourceRcount >= BaseWks.Rows.Count Then
                        MsgBox "Sorry there are not enough rows in the sheet"
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        'Copy the file name in column A
                        With sourceRange
                            BaseWks.cells(rnum, "A"). _
                                    Resize(.Rows.Count).Value = MyFiles(Fnum)
                        End With

                        'Set the destrange
                        Set destrange = BaseWks.Range("B" & rnum)

                        'we copy the values from the sourceRange to the destrange
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        rnum = rnum + SourceRcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next Fnum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With
End Sub

You can find more info here.

https://www.rondebruin.nl/win/s3/win008.htm

Upvotes: 0

paul bica
paul bica

Reputation: 10705

If VBA is not required, you could use DOS commands in the folder containing the CSVs

mergeCSVs.bat (in the CSV folder):

copy *.csv all.csv

echo Header1,Header2 > result.csv

type all.csv | findstr /v Header1,Header2 >> result.csv

del all.csv
  • copy *.csv all.csv - combines all CSVs into a new file all.csv (with repeating headers)
  • echo Header1,Header2 > result.csv - creates a new result.csv and writes the first row
  • type all.csv | findstr /v Header1,Header2 >> result.csv
    • type all.csv - extracts all data from all.csv
    • findstr /v Header1,Header2 - filters out all header rows from all.csv
    • >> result.csv - appends all this data into the result.csv
  • del all.csv - deletes temporary file all.csv

The results.csv will contain the merged data

csv1.csv:

Header1,Header2
Tim,Smith

csv2.csv:

Header1,Header2
Mike,Jones

result.csv:

Header1,Header2 
Tim,Smith
Mike,Jones

Notes:

  • both csv files contain an empty line at the end
  • they are comma-separated (not pipe-separated as in your example)

Upvotes: 1

Related Questions