CODEWITHSUNDEEP
rebolred-lang
user310291
user310291

Reputation: 38180

Why do I get error with show window in Rebol/Red?

When I click on button refresh, I get an error

v: [field1 "to refresh" field2 "to refresh" 
button "refresh" [show v]]
view v

How can refresh v ?

Update: I don't have error but it doesn't refresh:

    test: [
      ["a1" "b1"]
      ["a2" "b2"]  
    ]

    i: 1
    v: layout compose [
      field data test/:i/1 field data test/:i/2 button "refresh" [i: i + 1 show v]
    ]
    view v

Upvotes: 0

Views: 114

Answers (2)

Eran W
Eran W

Reputation: 1776

Not sure what you mean by "refresh", but Red's GUI is reactive, you don't need to explicitly tell it to update.

If you just want to update the text data (increment its value) - here's a short working example:

view [f: field "42" button "increment" [f/data: f/data + 1]]

That is, f is assigned to the just created field. On button press - it receives new value, by acessing its data member.

Upvotes: 0

sqlab
sqlab

Reputation: 6436

Show expects a face, not a block. You want probably something along

  v: layout [
     f1: field "to refresh" 
     f2: field "to refresh" 
     button "refresh" [f1/text: f2/text show v ]
  ]

To see a change you should type something in the second input field before clicking on the button.

To make something (usefully) working with your update you can use

i: 1
sw: true
v: layout compose [
    f1: field data test/:i/1 
    f2: field data test/:i/2 
    button "refresh" [
        i: pick [1 2] sw: not sw
        f1/text: test/:i/1
        f2/text: test/:i/2
        show v
    ]
]

show does not load the face definition block again, but the red-gui-system docs say

"Red/View will update both face and graphic objects in realtime as their properties are changed. This is the default behavior, but it can be switched off, when full control over screen updates is desirable. This is achieved by:

system/view/auto-sync?: off

When automatic syncing is turned off, you need to use show function on faces to get the graphic objects updated on screen."

I guess you can get something similar to your intention by destroying the old face object and building a new with the specification block.

 test: [
  ["a1" "b1"]
  ["a2" "b2"]  
]
i: 1
sw: true

vvw: layout v:  [
  field data test/:i/1 
  field data test/:i/2 
  button "refresh" [
      i: pick [1 2] sw: not sw
      unview vvw
      view v
  ]
]
view vvw

Upvotes: 1

Related Questions