CODEWITHSUNDEEP
neo4jcypher
Alexander Zhidkov
Alexander Zhidkov

Reputation: 581

Agregate cypher query

This is my database in Neo4j:

CREATE (Alex:Person {name:'Alex', phone:'0420965111'})
CREATE (Oxana:Person {name:'Oxana', email:'[email protected]'})
CREATE (Tango:Dance {name:'Tango'})
CREATE (Ballet:Dance {name:'Ballet'})
CREATE (Zouk:Dance {name:'Zouk'})
CREATE (Saturday:Day {name:'Saturday'})
CREATE (Sunday:Day {name:'Sunday'})
CREATE (Wednesday:Day {name:'Wednesday'})
MERGE (Alex)-[:LIKES]->(Tango)
MERGE (Alex)-[:LIKES]->(Zouk)
MERGE (Oxana)-[:LIKES]->(Tango)
MERGE (Oxana)-[:LIKES]->(Ballet)
MERGE (Alex)-[:AVAILABLE_ON]->(Sunday)
MERGE (Alex)-[:AVAILABLE_ON]->(Wednesday)
MERGE (Oxana)-[:AVAILABLE_ON]->(Sunday)
MERGE (Oxana)-[:AVAILABLE_ON]->(Saturday)

enter image description here

I need a list of more than 1 person who likes the same dance and available on the same day. How to write a query which returns this?: "Sunday", "Tango", ["Alex","Oxana"]

This almost works: match (p:Person), (d:Dance), (day:Day) where (p)-[:LIKES]->(d) and (p)-[:AVAILABLE_ON]->(day) return day.name, d.name, collect(p.name), count(*) But I don't know how to exclude records where count(*) is less than 2.

Upvotes: 2

Views: 40

Answers (1)

Bruno Peres
Bruno Peres

Reputation: 16355

You can use WITH:

match (p:Person), (d:Dance), (day:Day)
where (p)-[:LIKES]->(d) and (p)-[:AVAILABLE_ON]->(day)
with day.name as day, d.name as dance, collect(p.name) as names, count(*) as count
where count >= 2
return day, dance, names

From the docs:

The WITH clause allows query parts to be chained together, piping the results from one to be used as starting points or criteria in the next.

Also, you can add a constraint (WHERE clause) to filter data.

Upvotes: 1

Related Questions