Flex Truncating Button Labels

Question

First and foremost, I apologize for any vagueness in this question. At this point, I'm simply trying to get some new ideas of things to try in order to diagnose this bug.

Anyway, the problem I'm having is with an application that's using a custom moduleloader. That moduleloader has been compiled into an swc and the moduleloader is being instantiated via its namespace. This all works perfectly fine. The problem I'm encountering is specific to mx:button controls used within modules. For whatever reason, their labels are being truncated so, for example, Sign In is showing up with an ellipsis, as Sign ...

After quite a bit of fooling around I have been able to establish the following:

1. This problem only seems to occur within modules. If a button control is used in the main mxml, the label does not get truncated.
2. The button control whose label is being truncated does not have a width specified (setting its width to 100% or a specific pixel width doesn't fix the issue)
3. The button control is using the default padding (messing with the padding by setting left and right to 5 or any other value doesn't help matters either).
4. We are not using any embedded fonts so I've ruled that out as a possibility as well.
5. mx:CheckBox and mx:LinkButton are equally impacted by this problem although mx:CheckBox also seems to not want to show its checkbox, it just shows the truncated label.

A potential side affect of this is that attaching a dataprovider to mx:ComboBox causes the combobox control to throw a drawing error but I'm not entirely certain that it's related to the above problem.

One interesting thing I did find while perusing the net for an answer was a mention of fontContext and its relationship to IFlexModuleFactory. There's no specification for fontContext within our implementation of moduleloader so I'm not entirely certain if this could be the issue. In any case, if anyone has any ideas, it would be hugely appreciated. On the other hand, if you know exactly what ails me and can provide me with an answer, I might just wet myself with excitement. It's late. I'm tired. I NEED my Flex app to play nice.

Thanks in advance,

--Anne

Edit: To clarify what I'm looking for with this question, I really just need to know the following:

1. Could this issue be caused by a namespace conflict?
2. What else can potentially override the default behavior of labels if no CSS has been implemented?
3. Has anyone encountered a problem with inheritance being lost while using a custom implementation of moduleloader?
4. Has anyone encountered this problem or a similar problem with or without using moduleloader?

I'm not sharing any code with this question simply because I'd have to share the entire application and, unfortunately, I can't do that. Again, I'm not looking for the end all, be all solution, just some suggestions of things to look out for if anyone has any ideas.

Answer 1

I've had some success preventing Flex's erroneous button-label truncation by setting labelPlacement to "bottom", as in:

theButton.labelPlacement = ButtonLabelPlacement.BOTTOM;

Setting the label placement doesn't seem to help prevent truncation in some wider button sizes, but for many cases it works for me.

In cases where you can't use a bottom-aligned button label (such as when your button has a horizontally aligned icon), janusz's approach also seems to work. here's a version of janusz's .text reassignment technique in ActionScript rather than MXML:

theButton.addEventListener(FlexEvent.UPDATE_COMPLETE, function (e:FlexEvent):void {
  e.target.mx_internal::getTextField().text = e.target.label;
});

The preceding code requires you to import mx_internal and FlexEvent first, as follows: import mx.events.FlexEvent; import mx.core.mx_internal;

And here are the results…

Before (note truncation despite ample horizontal space):

After:

The only downside to this approach is you lose the ellipsis, but in my case I considered that a welcome feature.

Answer 2

I just came across this issue and solve it this way:

<mx:LinkButton label="Some label"
    updateComplete="event.target.mx_internal::getTextField().text = event.target.label"
/>;

Answer 3

I've used the custom button and link button class solutions and still ran into problems - but found a workaround that's worked every time for me.

Create a css style that includes the font you'd like to use for you label. Be sure to check 'embed this font' right under the text selection dropdown. Go back and apply the style to your button (or your custom button, depending on how long you've been bashing your hear against this particular wall), and voila!

Or should be voila...

Answer 4

I've been dealing with this issue myself, off and on and in various forms, for a year, and while I haven't figured out just what's causing it yet, there's clearly a mismeasurement happening somewhere along the line.

What I have been able to to, though, is work around it, essentially by subclassing button-type controls (in my case, Button, LinkButton, PopUpButton, et. al.) and assigning their textField members instances of a UITextField extension whose truncateToFit element simply returns false in all cases:

public class NonTruncatingUITextField extends UITextField
{
    public function NonTruncatingUITextField ()
    {
        super();
    }

    override public function truncateToFit(s:String = null):Boolean
    {
        return false;
    }
}

The custom component just extends Button (or whatever other button-type control is the culprit -- I've created a half-dozen or so of these myself, one for each type of control), but uses a NonTruncatingTextField as its label, where specified by the component user:

public class NonTruncatingButton extends Button
{
    private var _truncateLabel:Boolean;

    public function NonTruncatingButton()
    {
        super();

        this._truncateLabel = true;
    }

    override protected function createChildren():void
    {
        if (!textField)
        {
            if (!_truncateLabel)
                textField = new NonTruncatingUITextField();
            else
                textField = new UITextField();

            textField.styleName = this;

            addChild(DisplayObject(textField));
        }

        super.createChildren();
    }

    [Inspectable]
    public function get truncateLabel():Boolean
    {
        return this._truncateLabel;
    }

    public function set truncateLabel(value:Boolean):void
    {
        this._truncateLabel = value;    
    }   
}

... so then finally, in your MXML code, you'd reference the custom component thusly (in this case, I'm telling the control never to truncate its labels):

<components:NonTruncatingButton id="btn" label="Click This" truncateLabel="false" />

I agree it feels like a workaround, that the component architecture ought to handle all this more gracefully, and that it's probably something we're both overlooking, but it works; hopefully it'll solve your problem as you search for a more definitive solution. (Although personally, I'm using it as-is, and I've moved on to other things -- time's better spent elsewhere!)

Good luck -- let me know how it works out.