CODEWITHSUNDEEP
netlogo
Sunny Boyd
Sunny Boyd

Reputation: 15

Netlogo: calculate distance between self and other agent

Hello: I'm using Netlogo and want agents to calculate the distance between themselves and one other agent that they chose earlier. I keep getting the error of "expected a literal value." Code below. Help says that this reporter of distance "distance agent: Reports the distance from this agent to the given turtle or patch." Since I earlier defined "myneighbor," I can't figure out what is wrong. Any help most sincerely appreciated.

turtles-own [
  myneighbor                                 ;; closest other male frog to myself
  mycall                                     ;; the amplitude (loudness) of my own call
  myminthresh                                ;; when my neighbor's call is below this threshold, I move toward him
  mymaxthresh                                ;; when my neighbor's call is above this threshold, I move away from him
  myNND                                      ;; the distance to my nearest neighbor
  settle?                                    ;; true if male decides to create a territory and stop moving
 ]

to setup
  clear-all
  create-turtles population [                         ;; use the population slider to choose number of males

    set size 1.5                                      ;; easy to see but is it actual agent size or just agent image size?
    setxy random-xcor random-ycor                     ;; distribute frogs randomly in the landscape

    set mycall random 100                             ;; choose the amplitude of my own call from a random distribution 0 to 100
    set color scale-color red mycall 0 100            ;; allows easy visualization of variability in call amplitude
                                                      ;; lighter color is a higher amplitude
    set myminthresh inputminthresh                    ;; use the input on interface to set the min-threshold
    set mymaxthresh inputmaxthresh                    ;; use the input on the interface to set the max-threshold
    set myNND 0                                       ;; initialize nearest neighbor distance for all

  ]

  reset-ticks

end

to go
  choose-neighbors
  move-turtles
  tick
end

to choose-neighbors
   ask turtles [
    set myneighbor min-one-of other turtles [distance myself]  ;; choose my nearest neighbor based on distance
    set myNND  [ distance myneighbor ]
  ]
end

to move-turtles
  ask turtles [
    face myneighbor
    ;;set heading (random 360)
    fd 5
    pendown
  ]
end

Upvotes: 0

Views: 3156

Answers (1)

JenB
JenB

Reputation: 17678

The problem line is:

set myNND [ distance myneighbor ]

Change it to:

set myNND distance myneighbor

The [] conventions of NetLogo can be somewhat obscure.

Upvotes: 2

Related Questions