Can't get the written file content in q?

Question

I've copy the exact example in q for mortals as follows:

q)h:hopen `:D:/q4m/raw
q)h[42]
548i
q)h 10 20 30
548i
q)hclose h
q)get `:D:/q4m/raw
'D:/q4m/raw
  [0]  get `:D:/q4m/raw

Look into the directory, the file was created there. Why can't I get it?

Instead, if I do:

q)h:hopen `:D:/q4m/L
q)h[42]
628i
q)h[10 20 30]
628i
q)hclose h
q)get `:D:/q4m/L
0 1 2 3 4 42 10 20 30

Things get normal, why?

Answer 1

After testing the given code I believe your issue may be in how you intialise the file. I assume in the code that works that you use some variation of

 `:D:/q4m/L set til 5

before. However this is not done for

 `:D:/q4m/raw

If you were to use

 `:D:/q4m/raw set til 5

or alternatively

.[`:D:/q4m/raw;();:;()]

beforehand then the first set of code will work.

Additionally, if we look at the binary using

read1 `:D:/q4m/raw

and

read1 `:D:/q4m/L

and the output does not include 07 near the beginning then it is not being recognised as a proper kdb list. That is, hopen simply appends to the binary file instead of amending it. (If you notice the 05 byte that indicates length of the list, this doesn't increase when you add via the handle). eg. The first method you get

q)read1  `:D:/q4m/raw
0x2a000000000000000a0000000000000014000000000000001e00000000000000

which dosen't really mean anything in q. The second method gives

q)read1 `:D:/q4m/L
0xfe2007000000000005000000000000000000000000000000010000000000000002000000000..

which is a proper kdb list (notice the 07 which indicates type).

If you wish to instead just read in /q4m/raw then I suggest setting an empty list, hopen to that list and pass it `:D:/q4m/raw as follows

q)`:empty set 0#0
`:empty
q)h:hopen `:empty
q)h read1 `:D:/q4m/raw
3i
q)get `:empty
42 10 20 30

This will only work if all entries are the same type.