CODEWITHSUNDEEP
cmatrixcudatransposegpu-shared-memory
Luxii
Luxii

Reputation: 163

Matrix Transpose (with shared Memory) with arbitary size on Cuda C

I can't figure out a way to transpose a non-squared matrix using shared memory in CUDA C. (I am new to CUDA C and C)

In this blog post an efficient way was shown how to transpose a matrix (coalesced transpose via shared memory). But it only works for squared matrices.

Also Code is provided on github (same as on the blog).

On StackOverflow there is a similar question. There TILE_DIM = 16 is set. But with that implementation every thread just copies one element of the matrix to the result matrix.

This is my current implementation:

__global__ void transpose(double* matIn, double* matTran, int n, int m){
    __shared__ double tile[TILE_DIM][TILE_DIM];
    int i_n = blockIdx.x*TILE_DIM + threadIdx.x;
    int i_m = blockIdx.y*TILE_DIM + threadIdx.y; // <- threadIdx.y only between 0 and 7

    // Load matrix into tile
    // Every Thread loads in this case 4 elements into tile.
    int i;
    for (i = 0; i < TILE_DIM; i += BLOCK_ROWS){
        if(i_n < n  && (i_m+i) < m){
            tile[threadIdx.y+i][threadIdx.x] = matIn[n*(i_m+i) + i_n];
        } else {
            tile[threadIdx.y+i][threadIdx.x] = -1; 
        }
    }
    __syncthreads();

    for (i = 0; i < TILE_DIM; i += BLOCK_ROWS){
        if(tile[threadIdx.x][threadIdx.y+i] != -1){ // <- is there a better way?
            if(true){      // <- what should be checked here?
                matTran[n*(i_m+i) + i_n] = tile[threadIdx.x][threadIdx.y+i];
            } else {
                matTran[m*i_n + (i_m+i)] = tile[threadIdx.x][threadIdx.y+i];
            }
        }
    }
}

where 4 elements are copied from a thread into the tile. Also four elements from the tile are copied back into the result matrix.

Here the Kernel-Configuration <<<a, b>>>:

where a: (ceil(n/TILE_DIM), ceil(n/TILE_DIM))  (-> is casted to doubles) and 
      b: (TILE_DIM, BLOCK_ROWS) (-> (32, 8))

I am currently using the if(tile[threadIdx.x][threadIdx.y+i] != -1)-statement to determine, which thread should copy to the result matrix (There might be another way). As for my current knowledge, this behaves as follows: In a block, the thread index (x, y) copies the data into the tile and the thread index (y, x) copies the data back into the result matrix.

I inserted another if-statement to determine where to copy the data, as there are 2(?) possible destinations, depending on the thread index. Currently true is inserted there, but i tried many different things. The best I could come up with was if(threadIdx.x+1 < threadIdx.y+i), which transposes a 3x2-matrix successfully.

Can someone please explain, what I am missing by writing back into the result matrix? Obviously only one destination is correct. Using

matTran[n*(i_m+i) + i_n] = tile[threadIdx.x][threadIdx.y+i];

as on the blog mentioned should be correct, but I can't figure out, why it is not working for non-squared matrices?

Upvotes: 2

Views: 3575

Answers (2)

iocak28
iocak28

Reputation: 11

If you would like to speed-up your kernel even more then, you can use "Shared Memory Bank Conflicts" as shown here: https://developer.nvidia.com/blog/efficient-matrix-transpose-cuda-cc/

Simply, changing the tile initialization with this will help a lot:

__shared__ float tile[TILE_DIM][TILE_DIM+1];

Upvotes: 0

Luxii
Luxii

Reputation: 163

I was overcomplicating the problem. Here, the indeces are NOT swapped as i thought. They are recalculated using the Y- and X-Coordinate of the Thread/Block. Here is the snippet:

i_n = blockIdx.y * TILE_DIM + threadIdx.x;  
i_m = blockIdx.x * TILE_DIM + threadIdx.y

Here is the corrected code:

__global__ void transposeGPUcoalescing(double* matIn, int n, int m, double* matTran){
    __shared__ double tile[TILE_DIM][TILE_DIM];
    int i_n = blockIdx.x * TILE_DIM + threadIdx.x;
    int i_m = blockIdx.y * TILE_DIM + threadIdx.y; // <- threadIdx.y only between 0 and 7

    // Load matrix into tile
    // Every Thread loads in this case 4 elements into tile.
    int i;
    for (i = 0; i < TILE_DIM; i += BLOCK_ROWS){
        if(i_n < n  && (i_m+i) < m){
            tile[threadIdx.y+i][threadIdx.x] = matIn[(i_m+i)*n + i_n];
        }
    }
    __syncthreads();

    i_n = blockIdx.y * TILE_DIM + threadIdx.x; 
    i_m = blockIdx.x * TILE_DIM + threadIdx.y;

    for (i = 0; i < TILE_DIM; i += BLOCK_ROWS){
        if(i_n < m  && (i_m+i) < n){
            matTran[(i_m+i)*m + i_n] = tile[threadIdx.x][threadIdx.y + i]; // <- multiply by m, non-squared!

        }
    }
}

Thanks to this comment for noticing the error :)

Upvotes: 5

Related Questions