CODEWITHSUNDEEP
androidsdkloadswt
Chaoticandroid
Chaoticandroid

Reputation: 219

Android SDK/Android.bat does not find SWT.jar file

This is a follow-up to the issue SDK manager does not find java but the issue at hand now is the SDK/android.bat does not locate the SWT file.

I'm running Windows 7 x64, my file locations are as follows:

Android SDK (zip version) - C:\android-sdk-windows

SWT.jar (from the Zip)    - C:\android-sdk-windows\tools\lib\x86
                            C:\android-sdk-windows\tools\lib\x86_64

JDK 6 u24 x64             - C:\Program Files\Java\jdk1.6.0_24

My environment variables are as follows:

ANDROID_SWT = C:\android-sdk-windows\tools\lib\x86_64

Path        = ;C:\Program Files\Java\jdk1.6.0_24\bin

I am trying to solve the following issue.

Upon execution of the Android SDK manager, a black command screen quickly flashes and disappears, it doesn't start the SDK therefore I cannot download any of the platforms nor add-ons.

Note that I have those files already from the zip (platforms and ad-ons)

I've traced the culprit to the android.bat file but can't seem to figure it out. I've set the environment variable for the SWT.jar file.
I didn't modify the .bat file in any way so far.

The following is my bat file and the error is located near the bottom.

@echo off
rem Copyright (C) 2007 The Android Open Source Project
rem
rem Licensed under the Apache License, Version 2.0 (the "License");
rem you may not use this file except in compliance with the License.
rem You may obtain a copy of the License at
rem
rem      http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.

rem Useful links:
rem Command-line reference:
rem   http://technet.microsoft.com/en-us/library/bb490890.aspx

rem don't modify the caller's environment
setlocal

rem Set up prog to be the path of this script, including following symlinks,
rem and set up progdir to be the fully-qualified pathname of its directory.
set prog=%~f0

rem Grab current directory before we change it
set work_dir="%cd%"

rem Change current directory and drive to where the script is, to avoid
rem issues with directories containing whitespaces.
cd /d %~dp0


rem Check we have a valid Java.exe in the path.
set java_exe=
call lib\find_java.bat
if not defined java_exe goto :EOF

set jar_path=lib\sdkmanager.jar

rem Set SWT.Jar path based on current architecture (x86 or x86_64)
for /f %%a in ('%java_exe% -jar lib\archquery.jar') do set swt_path=lib\%%a

if "%1 %2"=="update sdk" goto StartUi
if not "%1"=="" goto EndTempCopy
:StartUi
echo [INFO] Starting Android SDK and AVD Manager

rem We're now going to create a temp dir to hold all the Jar files needed
rem to run the android tool, copy them in the temp dir and finally execute
rem from that path. We do this only when the launcher is run without
rem arguments, to display the SDK Updater UI. This allows the updater to
rem update the tools directory where the updater itself is located.

set tmp_dir=%TEMP%\temp-android-tool
xcopy %swt_path% %tmp_dir%\%swt_path% /I /E /C /G /R /Y /Q > nul
copy /B /D /Y lib\androidprefs.jar   %tmp_dir%\lib\        > nul
copy /B /D /Y lib\org.eclipse.*      %tmp_dir%\lib\        > nul
copy /B /D /Y lib\sdk*               %tmp_dir%\lib\        > nul
copy /B /D /Y lib\common.jar         %tmp_dir%\lib\        > nul
copy /B /D /Y lib\commons-compress*  %tmp_dir%\lib\        > nul

rem jar_path and swt_path are relative to PWD so we don't need to adjust them, just change dirs.
set tools_dir=%cd%
cd /d %tmp_dir%

:EndTempCopy

rem The global ANDROID_SWT always override the SWT.Jar path
if defined ANDROID_SWT set swt_path=%ANDROID_SWT%

if exist %swt_path% goto SetPath
    echo ERROR: SWT folder '%swt_path%' does not exist.
    echo Please set ANDROID_SWT to point to the folder containing swt.jar for your platform.
    goto :EOF

:SetPath
rem Finally exec the java program and end here.
call %java_exe% -Dcom.android.sdkmanager.toolsdir="%tools_dir%" -Dcom.android.sdkmanager.workdir=%work_dir% -classpath "%jar_path%;%swt_path%\swt.jar" com.android.sdkmanager.Main %*

rem EOF

This is what I get upon executing the bat file via command prompt

C:\Users\MuniFC Portable11>C:\android-sdk-windows\tools\android.bat
[INFO] Starting Android SDK and AVD Manager
'xcopy' is not recognized as an internal or external command, operable program or batch file.
No command line parameters provided, launching UI.
See 'android --help' for operations from the command line.
java.lang.NullPointerException
    at com.android.sdklib.internal.avd.AvdManager.parseAvdInfo(AvdManager.java:1205)
    at com.android.sdklib.internal.avd.AvdManager.buildAvdList(AvdManager.java:1184)
    at com.android.sdklib.internal.avd.AvdManager.<init>(AvdManager.java:385)
    at com.android.sdkuilib.internal.repository.UpdaterData.initSdk(UpdaterData.java:238)
    at com.android.sdkuilib.internal.repository.UpdaterData.<init>(UpdaterData.java:114)
    at com.android.sdkuilib.internal.repository.UpdaterWindowImpl.<init>(UpdaterWindowImpl.java:86)
    at com.android.sdkuilib.repository.UpdaterWindow.<init>(UpdaterWindow.java:42)
    at com.android.sdkmanager.Main.showMainWindow(Main.java:302)
    at com.android.sdkmanager.Main.doAction(Main.java:281)
    at com.android.sdkmanager.Main.run(Main.java:99)
    at com.android.sdkmanager.Main.main(Main.java:88)`

If you have any idea on how to fix this that would be awesome!

UPDATE

fixed the xcopy issue by adding the C:\windows\system32 to my Path variables, now the remaining issue is the SWT

Command Prompt run - Android.bat = 

C:\Users\MuniFC Portable11>C:\android-sdk-windows\tools\android.bat
[INFO] Starting Android SDK and AVD Manager
No command line parameters provided, launching UI.
See 'android --help' for operations from the command line.
java.lang.NullPointerException
        at com.android.sdklib.internal.avd.AvdManager.parseAvdInfo(AvdManager.java:1205)
        at com.android.sdklib.internal.avd.AvdManager.buildAvdList(AvdManager.java:1184)
        at com.android.sdklib.internal.avd.AvdManager.<init>(AvdManager.java:385)
        at com.android.sdkuilib.internal.repository.UpdaterData.initSdk(UpdaterData.java:238)
        at com.android.sdkuilib.internal.repository.UpdaterData.<init>(UpdaterData.java:114)
        at com.android.sdkuilib.internal.repository.UpdaterWindowImpl.<init>(UpdaterWindowImpl.java:86)
        at com.android.sdkuilib.repository.UpdaterWindow.<init>(UpdaterWindow.java:42)
        at com.android.sdkmanager.Main.showMainWindow(Main.java:302)
        at com.android.sdkmanager.Main.doAction(Main.java:281)
        at com.android.sdkmanager.Main.run(Main.java:99)
        at com.android.sdkmanager.Main.main(Main.java:88)

C:\Users\MuniFC Portable11>

Upvotes: 10

Views: 27790

Answers (7)

saravanan
saravanan

Reputation: 1

This solved my issue:

Open find_java.bat in the folder \sdk\tools\lib, on line 27.

find /i "x86" > NUL && set arch_ext=32 || set arch_ext=64

delete the blank between arch_ext=32 and ||, like arch_ext=32||, reopen the cmd, and all tools will work fine.

Upvotes: -1

serj
serj

Reputation: 508

Had the same problem when trying to open 'uiautomatorviewer.bat'. To fix it I added the ANDROID_SWT environment variable and also added the android_sdk/tools folder to the PATH.

I didn't manage to see the change until I've reopened the CMD.

Upvotes: -1

CTOD
CTOD

Reputation: 1

I'm running Android studio x64 on windows 8.1 pro x64. With JDK 8 x64 installed.

I had the same issue running the AVD from Android Studio. Below is the fix:

Edit system environment variables... using windows search just type environment variables and it will open up the editor. Add a new system variable titled ANDROID_SWT. If it is already there no need to add another. Set the "variable value" to the path where the swt.jar is. I found my via:

C:....\android-studio\sdk\tools\lib\x86_64\swt.jar

I then just copied and pasted that path into the new (or existing) ANDROID_SWT system variables value. Then I pressed OK to save the new system variable and it's new value (which is the path to the swt.jar), closed and reopened Android Studio and the AVD started up!

Hope this helps

Upvotes: -1

AiBeatsStupidity
AiBeatsStupidity

Reputation: 11

OK so I had this problem as well in environment variables, ANDROID_SWT=libx86_64, and move both android and java to c:\ I also didn't modify android.bat in the working fix.

Upvotes: -1

passer
passer

Reputation: 31

I have the same problem with you.

Finally, I clear this problem by rename the java and android sdk folder without empty char.

At Begin, java is installed in D:\Program Files\Java and android sdk is installed in D:\Program Files\Android.

Change to D:\Java and D:\Android respectively and add D:\Java\jdk1.7.0_04\bin to PATH, and it appear.

Upvotes: 3

Rafael P. G.
Rafael P. G.

Reputation: 16

I had the same problem once, and clearing the avd folder (config of the virtual devices) work for me...you should try it. Seams that the problem was a corrupt avd which cause the android.bat script to fail when parsing it.

Upvotes: 0

JohnTheHero
JohnTheHero

Reputation: 61

After adding C:\windows\system32 to PATH xcopy error is gone, but android.bat still had problem with swt.jar. Removing ANDROID_SWT variable worked for me.

Upvotes: 6

Related Questions