parse JSON from PERL

Question

I get a response from the server in json format. I decompose it using Data::Dumper, giving

$VAR1 = {
  'StatementsResponse' => {
    'ResponceRef' => '',
    'statements' => [
      {
        'J0115AOU3H' => {
          'BPL_DAT_KL' => '10.01.2019',
          'AUT_MY' => '10'
        }
      },
      {
        'J0115A47J7' => {
          'AUT_MY' => '11',
          'BPL_DAT_KL' => '11.01.2019'
        }
      },
      {
        'J0115AVR8L' => {
          'BPL_DAT_KL' => '12.01.2019',
          'AUT_MY' => '12'
        }
      },
      {
        'J0115AVBGS' => {
          'AUT_MY' => '13',
          'BPL_DAT_KL' => '13.01.2019'
        }
      }
    ]
  }
};

How do I get the values ​​BPL_DAT_KL and AUT_MY, provided that J0115AOU3H is a dynamic value that changes constantly and is not known at the time of the output? If I know the value, then I can get the values ​​with the code below, but what if I don’t know it?

use JSON;
use JSON::XS;
my $json = `cat /home/json.log`;
my $data=decode_json($json);

use Data::Dumper;
print Dumper($data);

my $aref = $data->{'StatementsResponse'}->{'statements'};
for my $element (@$aref) {
    print $element->{J0115AOU3H}->{BPL_SUM_E};
}

Answer 1

my $statements = $data->{StatementsResponse}{statements};
for my $statement (@$statements) {
    for my $statement_id (keys(%$statement)) {
        my $statement_data = $statement->{$statement_id};
        say $statement_data->{BPL_SUM_E};
    }
}

If we can rely on the hashes only having one element, you have a very weird format, and the above can be simplified to the following:

my $statements = $data->{StatementsResponse}{statements};
for my $statement (@$statements) {
    my ($statement_id) = keys(%$statement);
    my $statement_data = $statement->{$statement_id};
    say $statement_data->{BPL_SUM_E};
}