CODEWITHSUNDEEP
sqlms-access
Ramski
Ramski

Reputation: 3

Adding a sequential index on a table ordered by three fields

I have table a with fields a.A, a.B, a.C.

I am trying to make table b with fields b.A, b.B, b.C, b.D with a query:

SELECT a.A, a.B, a.C, 
(Sequential integers from first record returned to last record returned) AS D 
into b
FROM a WHERE a.C is not null
ORDER BY a.C, a.B DESC, a.A;

Sample output of table b:

A, B, C, D
9500, 106.12, 9507, 1
9507, 106.12, 9516, 2
9485, 106.11, 9516, 3
9472, 106.1, 9516, 4
9432, 106.09, 9516, 5
9528, 106.14, 9531, 6
9523, 106.13, 9536, 7
9531, 106.14, 9540, 8
9540, 106.14, 9545, 9
9545, 106.14, 9548, 10
9548, 106.14, 9555, 11
9570, 106.21, 9572, 12
9575, 106.22, 9580, 13
9580, 106.22, 9583, 14

A is a unique identifier.

This will run on a table with millions of records.

My challenge is with (Sequential ascending integers from first record returned to last record returned). Does anyone have a suggestion on what to put in the parentheses that will help me create table b using only a query?

Upvotes: 0

Views: 46

Answers (2)

Gustav
Gustav

Reputation: 55841

You can use my function RowNumber:

' Builds consecutive row numbers in a select, append, or create query
' with the option of a initial automatic reset.
' Optionally, a grouping key can be passed to reset the row count
' for every group key.
'
' 2018-08-23. Gustav Brock, Cactus Data ApS, CPH.
'
Public Function RowNumber( _
    ByVal Key As String, _
    Optional ByVal GroupKey As String, _
    Optional ByVal Reset As Boolean) _
    As Long

    ' Uncommon character string to assemble GroupKey and Key as a compound key.
    Const KeySeparator      As String = "¤§¤"
    ' Expected error codes to accept.
    Const CannotAddKey      As Long = 457
    Const CannotRemoveKey   As Long = 5

    Static Keys             As New Collection
    Static GroupKeys        As New Collection
    Dim Count               As Long
    Dim CompoundKey         As String

    On Error GoTo Err_RowNumber

    If Reset = True Then
        ' Erase the collection of keys and group key counts.
        Set Keys = Nothing
        Set GroupKeys = Nothing
    Else
        ' Create a compound key to uniquely identify GroupKey and its Key.
        ' Note: If GroupKey is not used, only one element will be added.
        CompoundKey = GroupKey & KeySeparator & Key
        Count = Keys(CompoundKey)

        If Count = 0 Then
            ' This record has not been enumerated.
            '
            ' Will either fail if the group key is new, leaving Count as zero,
            ' or retrieve the count of already enumerated records with this group key.
            Count = GroupKeys(GroupKey) + 1
            If Count > 0 Then
                ' The group key has been recorded.
                ' Remove it to allow it to be recreated holding the new count.
                GroupKeys.Remove (GroupKey)
            Else
                ' This record is the first having this group key.
                ' Thus, the count is 1.
                Count = 1
            End If
            ' (Re)create the group key item with the value of the count of keys.
            GroupKeys.Add Count, GroupKey
        End If
        ' Add the key and its enumeration.
        ' This will be:
        '   Using no group key: Relative to the full recordset.
        '   Using a group key:  Relative to the group key.
        ' Will fail if the key already has been created.
        Keys.Add Count, CompoundKey
    End If

    ' Return the key value as this is the row counter.
    RowNumber = Count

Exit_RowNumber:
    Exit Function

Err_RowNumber:
    Select Case Err
        Case CannotAddKey
            ' Key is present, thus cannot be added again.
            Resume Next
        Case CannotRemoveKey
            ' GroupKey is not present, thus cannot be removed.
            Resume Next
        Case Else
            ' Some other error. Ignore.
            Resume Exit_RowNumber
    End Select

End Function

and an append query similar to this:

INSERT INTO TempTable ( [RowID] )
SELECT RowNumber(CStr([ID])) AS RowID, *
FROM SomeTable
WHERE (RowNumber("","",True)=0);

Full description including a demo can be found here:

Sequential Rows in Microsoft Access

and on GitHub: VBA.RowNumbers

Upvotes: 1

Gordon Linoff
Gordon Linoff

Reputation: 1269923

I think the simplest method is to define the new table first and use insert:

create table b (
    b_id autoincrement primary key,
    a ?,  -- ? is for the type of the column
    b ?,
    c ?
);

insert into b (a, b, c)
    select a.A, a.B, a.C, 
    from a 
    where a.C is not null
    orer by a.C, a.B desc, a.A;

MS Access does not have a convenient function such as row_number() (supported by almost all other databases) to make this simpler.

Upvotes: 1

Related Questions