CODEWITHSUNDEEP
xsltxpath
topskip
topskip

Reputation: 17345

How to partition dates with XSLT

I have a group of dates and I'd like to create partitions with a criterion such as "exactly 7 days apart" For example this is my source xml:

<root>
  <entry date="2019-05-12" />
  <entry date="2019-05-19" />
  <entry date="2019-05-26" />
  <entry date="2019-06-16" />
  <entry date="2019-06-23" />
</root>

The result should be like this:

<root>
   <group>
      <val>12.5.</val>
      <val>19.5.</val>
      <val>26.5.</val>
   </group>
   <group>
      <val>16.6.</val>
      <val>23.6.</val>
   </group>
</root>

since the first three and the last two dates are all on a Sunday without a gap.

What I have so far is this:

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:sd="urn:someprefix"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="#all"
  >

  <xsl:output indent="yes"/>

  <xsl:template match="root">
    <root>
      <xsl:copy-of select="sd:partition(distinct-values(for $i in entry/@date return $i cast as xs:date))"/>
    </root>
  </xsl:template>

  <xsl:function name="sd:partition">
    <xsl:param name="dates" as="xs:date*"/>
    <xsl:for-each-group select="$dates" group-adjacent="format-date(., '[F]')">
      <group>
        <xsl:for-each select="current-group()">
          <val>
            <xsl:value-of select="format-date(.,'[D].[M].')"/>
          </val>
        </xsl:for-each>
      </group>
    </xsl:for-each-group>
  </xsl:function>
</xsl:stylesheet>

Which only generates one group.

How can I ask for the previous element to be 7 days apart? I know of duration (xs:dayTimeDuration('P1D')), but I don't know how to compare it to a previous value.

I use Saxon 9.8 HE.

Upvotes: 0

Views: 61

Answers (2)

Martin Honnen
Martin Honnen

Reputation: 167706

I think you can also do it using group-adjacent:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="#all"
    expand-text="yes"
    version="3.0">

  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="root">
      <xsl:copy>
          <xsl:for-each-group select="entry/@date/xs:date(.)"
            group-adjacent=". -  (position() - 1) * xs:dayTimeDuration('P7D')">
              <group>
                  <xsl:apply-templates select="current-group()"/>
              </group>
          </xsl:for-each-group>
      </xsl:copy>
  </xsl:template>

  <xsl:template match=".[. instance of xs:date]">
      <val>{format-date(.,'[D].[M].')}</val>
  </xsl:template>

</xsl:stylesheet>

https://xsltfiddle.liberty-development.net/ncdD7mM

Upvotes: 3

Tim C
Tim C

Reputation: 70638

To do your grouping, you really need to know the difference in days with the previous element, then you can group starting with dates where the difference is not 7 days. So, you can declare a variable where you build up some new XML with the dates and differences, and then use that to group.

Try this function in your XSLT instead.

<xsl:function name="sd:partition">
    <xsl:param name="dates" as="xs:date*"/>

    <xsl:variable name="datesWithDiff" as="element()*">
      <xsl:for-each select="$dates">
        <xsl:variable name="pos" select="position()" />
        <date diff="{(. - $dates[$pos - 1]) div xs:dayTimeDuration('P1D')}">
          <xsl:value-of select="." />
        </date>   
      </xsl:for-each>
    </xsl:variable>

    <xsl:for-each-group select="$datesWithDiff" group-starting-with="date[@diff = '' or xs:int(@diff) gt 7]">
      <group>
        <xsl:for-each select="current-group()">
          <val>
            <xsl:value-of select="format-date(.,'[D].[M].')"/>
          </val>
        </xsl:for-each>
      </group>
    </xsl:for-each-group>
</xsl:function>

Upvotes: 1

Related Questions