CODEWITHSUNDEEP
matplotlibjulia
Mikael Fremling
Mikael Fremling

Reputation: 772

Julia @eval world age missmatch

I'm trying to use the julia @eval functionality to only load the PyPlot package on demand. However I verry often run into world age missmatch. Here is a minimal example where i try and plot on demand 

function CreateMatrix(Ncount;Plot=true)
    TheMatrix = fill(0.0,Ncount,Ncount)

    if Plot
        @eval using PyPlot
        ###"Plot the Matrix"
        PyPlot.figure()
        PyPlot.imshow(abs.(TheMatrix))
        PyPlot.colorbar()
    end
    return TheMatrix
end

CreateMatrix(10;Plot=false)
CreateMatrix(10;Plot=true)

With the output

ERROR: LoadError: MethodError: no method matching figure()
The applicable method may be too new: running in world age 25063, while current world is 25079.
Closest candidates are:
  figure(!Matched::Any...; kws...) at ~/.julia/packages/PyPlot/fZuOQ/src/PyPlot.jl:148 (method too new to be called from this world context.)
Stacktrace:
 [1] #CreateMatrix#3(::Bool, ::Function, ::Int64) at myfile.jl:7
 [2] (::getfield(Main, Symbol("#kw##CreateMatrix")))(::NamedTuple{(:Plot,),Tuple{Bool}}, ::typeof(CreateMatrix), ::Int64) at ./none:0
 [3] top-level scope at none:0
 [4] include at ./boot.jl:317 [inlined]
 [5] include_relative(::Module, ::String) at ./loading.jl:1044
 [6] include(::Module, ::String) at ./sysimg.jl:29
 [7] exec_options(::Base.JLOptions) at ./client.jl:231
 [8] _start() at ./client.jl:425
in expression starting at myfile.jl:16

Does anyone know how uses the @eval functionality properly?

EDIT

One of the comments suggested wrapping the plotting command and annotating with @noinline as below, but this does not work.

function CreateMatrix(Ncount;Plot=false)
    TheMatrix = fill(0.0,Ncount,Ncount)

    if Plot
        @eval using PyPlot
        ###"Plot the Matrix"
        ThePlotting(TheMatrix)
    end
    return TheMatrix
end

@noinline function ThePlotting(TheMatrix)
    PyPlot.figure()
    PyPlot.imshow(abs.(TheMatrix))
    PyPlot.colorbar()
end

CreateMatrix(10;Plot=false)
CreateMatrix(10;Plot=true)

I'm running julia version 1.0.2

Upvotes: 1

Views: 211

Answers (1)

Bogumił Kamiński
Bogumił Kamiński

Reputation: 69949

You can implement it like this:

function CreateMatrix(Ncount;Plot=true)
    TheMatrix = fill(0.0,Ncount,Ncount)

    if Plot
        if isdefined(Main, :PyPlot)
            println("PyPlot already loaded")
            PyPlot.figure()
            PyPlot.imshow(abs.(TheMatrix))
            PyPlot.colorbar()
        else
            println("PyPlot loading PyPlot")
            @eval using PyPlot
            Base.invokelatest(PyPlot.figure)
            Base.invokelatest(PyPlot.imshow, abs.(TheMatrix))
            Base.invokelatest(PyPlot.colorbar)
        end
    end
    return TheMatrix
end

I have used conditional to allow you to see which branch gets executed on repeated call to the function.

Initially I thought that when calling non-inlined function Julia allows world age change (but it turns out that it is strict).

Finally - in general it is probably safer not to write code like this but simply load the module in top-level scope (possibly conditionally).

Upvotes: 1

Related Questions