CODEWITHSUNDEEP
xsltforeachconcatenationxslt-1.0
Caerule
Caerule

Reputation: 5

XSLT: How do I use a concatenated string as a variable name with xsl:for-each select?

I'm being put on a system migration project, and my task is to receive a SOAP XML request from System A, then convert 6 parameter names inside the request into new names readable by System B, and output a file with just the parameters changed. (all param names changed)

Request:

<q0:Command>
 <q0:Transaction>
  <q0:Operation namespace="Provisioning" name="Create" modifier="Data">
   <q0:ParameterList>
    <q0:StringParameter name="Action">Create</q0:StringParameter>
    <q0:StructParameter name="Create">
     <q0:StringParameter name="UserID">1234567X</q0:StringParameter>
     <q0:StringParameter name="Device1">abcd567890</q0:StringParameter>
     <q0:StringParameter name="Contract1">Postpaid</q0:StringParameter>
     <q0:StringParameter name="Line1">990108024011900</q0:StringParameter>
     <q0:StringParameter name="Device2">efgh567890</q0:StringParameter>
     <q0:StringParameter name="Contract2">Postpaid</q0:StringParameter>
     <q0:StringParameter name="Line2">990104562499105</q0:StringParameter>
    </q0:StructParameter>
   </q0:ParameterList>
  </q0:Operation>
 </q0:Transaction>
</q0:Command>

First, I just manually recreated each param with the new name in a for-each select block, and it worked. The situation is, there is now a requirement that the values shouldn't be hardcoded one-by-one, but instead checked in a loop (Just in case the number of devices per user increases).

So I thought of declaring a $LoopIndex variable, and concatenating it to strings that match the parameter names, like so:

So I implemented Tim's answer below into my for-each section, like so:

<xsl:for-each select="//q0:CommandRequestData/q0:Command/q0:Transaction/q0:Operation/q0:ParameterList/q0:StructParameter[@name='Create']">
 <xsl:for-each select="q0:StringParameter">
  <xsl:choose>
   <xsl:when test="@name = 'UserID'">
    <ins:Parameter name="USER_ID" value="{string()}" />
   </xsl:when>
   <xsl:when test="starts-with(@name, 'Device')">
    <ins:Parameter name="concat('DEVICE_ID_', substring(., 7))" value="{string()}" />
   </xsl:when>
   <xsl:when test="starts-with(@name, 'Contract')">
    <ins:Parameter name="concat('CONTRACT_TYPE_', substring(., 9))" value="{string()}" />
   </xsl:when>
   <xsl:when test="starts-with(@name, 'Line')">
    <ins:Parameter name="concat('LINE_ID_', substring(., 5))" value="{string()}" />
   </xsl:when>
  </xsl:choose>
 </xsl:for-each>
</xsl:for-each>

And the above code isn't working. The page isn't understanding that I mean "@name='Device1'" when I say "@name=concat('Device', $LoopIndex)". Is this kind of thing possible with XSLT or will I need to stick to hardcoding the parameter assignments?

Unfortunately, it's only semi-successful. The page is literally taking the "concat('DEVICE_ID_', substring(., 7))" as a string for the parameter name, instead of performing the concatenation.

Update: Got inspired by Tim's answer and found a 'simple' way of using position() to just increment the numbers:

<xsl:for-each select="//q0:CommandRequestData/q0:Command/q0:Transaction/q0:Operation/q0:ParameterList/q0:StructParameter[@name='Create']">
 <xsl:for-each select="q0:StringParameter[@name='UserID']">
  <ins:Parameter name="USER_ID" value="{string()}" />
 </xsl:for-each>
 <xsl:for-each select="q0:StringParameter[starts-with(@name, 'Device')]">
  <xsl:variable name="DeviceIndex" select="position()" />
  <ins:Parameter name="DEVICE_ID_{$DeviceIndex}" value="{string()}" />
 </xsl:for-each>
 <xsl:for-each select="q0:StringParameter[starts-with(@name, 'Contract')]">
  <xsl:variable name="ContractIndex" select="position()" />
  <ins:Parameter name="CONTRACT_TYPE_{$ContractIndex}" value="{string()}" />
 </xsl:for-each>
 <xsl:for-each select="q0:StringParameter[starts-with(@name, 'Line')]">
  <xsl:variable name="LineIndex" select="position()" />
  <ins:Parameter name="LINE_ID_{$LineIndex}" value="{string()}" />
 </xsl:for-each>
</xsl:for-each>

The resulting SOAP XML request passed to System B now successfully looks like below. It's not arranged like the SOAP request...but I'll take it! :)

<q0:Command>
 <q0:Transaction>
  <q0:Operation namespace="Provisioning" name="Create" modifier="Data">
   <q0:ParameterList>
    <q0:StringParameter name="Action">Create</q0:StringParameter>
    <q0:StructParameter name="Create">
     <ins:Parameter name="USER_ID" value="1234567X"/>
     <ins:Parameter name="DEVICE_ID_1" value="abcd567890"/>
     <ins:Parameter name="DEVICE_ID_2" value="efgh567890"/>
     <ins:Parameter name="CONTRACT_TYPE_1" value="Postpaid"/>
     <ins:Parameter name="CONTRACT_TYPE_2" value="Postpaid"/>
     <ins:Parameter name="LINE_ID_1" value="990108024011900"/>
     <ins:Parameter name="LINE_ID_2" value="990104562499105"/>
    </q0:StructParameter>
   </q0:ParameterList>
  </q0:Operation>
 </q0:Transaction>
</q0:Command>

Upvotes: 0

Views: 1124

Answers (1)

Tim C
Tim C

Reputation: 70638

I would use template matching here on the attribute, along with the identity template, rather than xsl:for-each and xsl:choose, just to keep the code cleaner (although it is not strictly necessary to solve your problem).

But to solve your problem you can use string functions to extract the current number from the @name attribute.

Try this XSLT

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:q0="q0" >
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="q0:StructParameter[@name='Create']/q0:StringParameter/@name">
    <xsl:attribute name="name">
      <xsl:choose>
        <xsl:when test=". = 'UserID'">
          <xsl:text>USER_ID</xsl:text>
        </xsl:when>
        <xsl:when test="starts-with(., 'Device')">
          <xsl:value-of select="concat('DEVICE_ID_', substring(., 7))" />
        </xsl:when>
        <xsl:when test="starts-with(., 'Contract')">
          <xsl:value-of select="concat('CONTRACT_TYPE_', substring(., 9))" />
        </xsl:when>
        <xsl:when test="starts-with(., 'Line')">
          <xsl:value-of select="concat('LINE_ID_', substring(., 5))" />
        </xsl:when>
        <xsl:otherwise>NA</xsl:otherwise>
      </xsl:choose>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

Note that you would have to change the namespace URI for q0 to match your actual one accordingly.

Upvotes: 1

Related Questions