CODEWITHSUNDEEP
graphgnuplot
Marcia Cross
Marcia Cross

Reputation: 37

How to plot two graphs above?

How to 1) have one legent 2) make the first graph higher 3) plot secont data in first graph 4) have one x-axes - lower graph 5) minimalize space between graphs 6) have the same width of graphs

Thank you

set multiplot layout 2,1
set tmargin 1.8
set bmargin 1.8
set encoding iso_8859_1


unset xlabel
set ylabel "{/:Italic F} [a. u.]" font "Segoe UI,12"
set ytics nomirror font "Segoe UI,12"
set xtics nomirror font "Segoe UI,12"
#set decimalsign ','
set format y "%.2f"
set key at graph 0.78,1 font "Segoe UI,12"
set key out horiz font "Segoe UI,12"
set key tc variable
plot [4272:4500] [0.7:1.02] 'data1.txt' using 1:2 title "F" with lines linecolor rgb "red" lw 1.5, "data2.txt' using 1:3 title "D" with lines linecolor rgb "black" lw 1.5


set xlabel "{/:Italic {/Symbol l}} ({\305})" font "Segoe UI,12"
set ylabel "{/:Italic F} [a. u.]" font "Segoe UI,12"
set ytics nomirror font "Segoe UI,12"
set xtics nomirror font "Segoe UI,12"
#set decimalsign ','
set format y "%.2f"
set key at graph 0.78,1 font "Segoe UI,12"
set key out horiz font "Segoe UI,12"
set key tc variable
plot [4272:4500] 'data1.txt' using 1:4 title "DD - fitted" with lines linecolor rgb "navy" lw 1.5

error:

plot 'data1.txt' using 1:2 title "Fid" with lines linecolor rgb "red" lw 1.5,"data1.txt' using 1:3 title "Measured" with lines linecolor rgb "bla
ck" lw 1.5"
                                                                                                                        ^
           unexpected or unrecognized token

Upvotes: 0

Views: 94

Answers (1)

grsousajunior
grsousajunior

Reputation: 778

Something like this?

reset
set encoding utf8

set tics out nomirror

set style line 1 lc "red"
set style line 2 lc "orange"
set style line 3 lc "blue"

unset xtics
set  ytics
set  ylabel "y-axes"  #tc ls 1

set lmargin screen 0.10
set rmargin screen 0.95


set multiplot layout 2,1

set bmargin screen 0.40
set key Left reverse out horiz

set xrange [0:10]
set yrange [0:10] 

plot \
    x w l ls 1 t "x",\
    x + 5 w l ls 2 t "x + 5",\
    1/0 w l ls 3 t "1/0"

set tmargin screen 0.37
set bmargin screen 0.15

#set key left Left reverse
unset key

set tics out nomirror
set  xlabel "x-axes (λαβϵλ = label)"

plot x w l ls 3 t "x"

Result graph

Upvotes: 1

Related Questions