CODEWITHSUNDEEP
wolfram-mathematicamathematica-frontend
Alexey Popkov
Alexey Popkov

Reputation: 9425

Styling 3D plots as it was in Mathematica 5

I like quiet and undisturbed color gamut and lighting of 3D plots in Mathematica 5.

Is it possible to style 3D plots in Mathematica 7 exactly as it was in Mathematica 5?

Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}, ImageSize -> 360]
<< Version5`Graphics`
Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}, ImageSize -> 360]

Screenshot of the Output

This code allows to compare easily visual appearance of version 5 and version 7 graphics:

v5style = {{"Ambient", RGBColor[{0.356, 0.294, 0.4}]}, {"Directional",
     RGBColor[{0.56, 0., 0.}], 
    ImageScaled[{2, 0, 2}]}, {"Directional", RGBColor[{0., 0.56, 0.}],
     ImageScaled[{2, 2, 2}]}, {"Directional", 
    RGBColor[{0., 0., 0.56}], ImageScaled[{0, 2, 2}]}};

PostScriptGraphics /: MakeBoxes[PostScriptGraphics[str_String], _] := 
 Cell[GraphicsData["PostScript", str], CellAutoOverwrite -> True, 
  CellBaseline -> Center]
v5vsv7[\[Theta]_] := {Developer`LegacyGraphics[];
   v5Graphics = 
    Graphics`Legacy`Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}, 
     ImageSize -> 360, 
     ViewPoint -> RotationTransform[\[Theta], {0, 0, 1}][{3, 0, 3}]];
   v5PostScript = ExportString[v5Graphics, "APS"];
   Developer`SymbolicGraphics[];
   PostScriptGraphics[v5PostScript],
   Graphics3D[First@Graphics3D@v5Graphics, 
     FilterRules[Last@Graphics3D@v5Graphics, Options[Graphics3D]], 
     ViewPoint -> RotationTransform[\[Theta], {0, 0, 1}][{3, 0, 3}], 
     PlotRangePadding -> None, 
     ImageSize -> 360] /. (Lighting -> _) -> (Lighting -> v5style)};

Grid@Table[v5vsv7[\[Theta]], {\[Theta], 0, 2 Pi, Pi}]

Upvotes: 3

Views: 987

Answers (2)

DavidC
DavidC

Reputation: 3066

Mr. W already answered your question well, I think. Here's a toy to play around with some possibilities, including other palettes. It starts with the values Mr. W used.

Manipulate[
  Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}, PlotLabel -> cf, 
  ImageSize -> 360, ColorFunction -> cf, Mesh -> mesh,
  Lighting -> {{"Ambient", cs},
    {"Directional", RGBColor[{s, 0., 0.}], 
     ImageScaled[{2, 0, 2}]}, {"Directional", RGBColor[{0., s, 0.}], 
     ImageScaled[{2, 2, 2}]}, {"Directional", RGBColor[{0., 0., s}], 
     ImageScaled[{0, 2, 2}]}}],
{{cf, None, "color function"}, Prepend[ColorData["Gradients"], None]},
{{cs, RGBColor[{0.356, 0.294, 0.4}]}, ColorSlider},
{{s, .5, "brightness"}, 0, 1, Appearance -> "Labeled"},
{{mesh, 15}, 0, 30, 1, Appearance -> "Labeled"}]

manipulatte

Upvotes: 4

Mr.Wizard
Mr.Wizard

Reputation: 24336

Is this approaching close enough, or still a long way off of your requirements?

new = {{"Ambient", RGBColor[{0.356, 0.294, 0.4}]}, {"Directional", 
  RGBColor[{0.56, 0., 0.}], ImageScaled[{2, 0, 2}]}, {"Directional", 
  RGBColor[{0., 0.56, 0.}], ImageScaled[{2, 2, 2}]}, {"Directional", 
  RGBColor[{0., 0., 0.56}], ImageScaled[{0, 2, 2}]}};

Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}, Lighting -> new, Mesh -> 20]

enter image description here

Upvotes: 1

Related Questions