CODEWITHSUNDEEP
blockchainethereumsolidity
venus12
venus12

Reputation: 523

Data location must be "memory" for return parameter in function, but none was given

I tried solidity example like as above in remix, solidity version > 0.5.0 But I am getting this error now. What is the way to solve this error?

contract MyContract {
    string value;

    function get() public view returns (string) {
        return value;
    }

    function set(string _value) public {
        value = _value;
    }

    constructor() public {
        value = "myValue";
    }
}

Upvotes: 52

Views: 44367

Answers (5)

Istiaque Ahmed
Istiaque Ahmed

Reputation: 9

pragma solidity 0.8.11;

contract Greeter{

    string greeting;

    function greeter(string memory _greeting) public{
        greeting = _greeting;

    }

    function greet() public returns(string memory)
    {
        return greeting;
    }

}

Upvotes: -3

Gargi Kantesaria
Gargi Kantesaria

Reputation: 77

In the case of returning address array, you can declare memory after your return address type.

function getAllPlayers() public view returns(address[] memory){
        return players;
    }

Upvotes: 4

Ahmad Altayeb
Ahmad Altayeb

Reputation: 386

Values of reference type can be modified through multiple different names. Contrast this with value types where you get an independent copy whenever a variable of value type is used. Because of that, reference types have to be handled more carefully than value types. Currently, reference types comprise structs, arrays and mappings. If you use a reference type, you always have to explicitly provide the data area where the type is stored: memory (whose lifetime is limited to an external function call), storage (the location where the state variables are stored, where the lifetime is limited to the lifetime of a contract) or calldata (special data location that contains the function arguments).

Warning

Prior to version 0.5.0 the data location could be omitted, and would default to different locations depending on the kind of variable, function type, etc., but all complex types must now give an explicit data location.

https://docs.soliditylang.org/en/latest/types.html#reference-types

so you have to put memory or calldata after String as follows:

contract MyContract {
    string value;

    function get() public view returns (string memory) {
        return value;
    }

    function set(string memory _value) public {
        value = _value;
    }

    constructor() {
        value = "myValue";
    }
}

another thing to notice that you dont have to put public in the constructor any more:

Warning: Prior to version 0.7.0, you had to specify the visibility of constructors as either internal or public.

https://docs.soliditylang.org/en/latest/contracts.html?highlight=constructor#constructors

Upvotes: 18

Shaurya Chaturvedi
Shaurya Chaturvedi

Reputation: 1

Solidity is updated on a daily basis so there are changes made of which you should be aware of. For that keep referring to the updated solidity docs.

The Code should be this:

contract MyContract {
    string value;

    function get() public view returns (string memory) {
        return value;
    }

    function set(string memory _value) public {
        value = _value;
    }

    constructor() public {
        value = "myValue";
    }
}

OR

contract MyContract {
    string value;

    function get() public view returns (string calldata) {
        return value;
    }

    function set(string calldata _value) public {
        value = _value;
    }

    constructor() public {
        value = "myValue";
    }
}

Upvotes: 0

Dushyanth Kumar Reddy
Dushyanth Kumar Reddy

Reputation: 1232

You should add memory keyword for string parameter, which was introduced in solidity version 0.5.0

As per the documentation:

Explicit data location for all variables of struct, array or mapping types is now mandatory. This is also applied to function parameters and return variables. For example, change uint[] x = m_x to uint[] storage x = m_x, and function f(uint[][] x) to function f(uint[][] memory x) where memory is the data location and might be replaced by storage or calldata accordingly. Note that external functions require parameters with a data location of calldata.

Corrected code

contract MyContract {
    string value;

    function get() public view returns (string memory) {
        return value;
    }

    function set(string memory _value) public {
        value = _value;
    }

    constructor() public {
        value = "myValue";
    }
}

Refer to official documentation on breaking changes made in version 0.5.0

Upvotes: 86

Related Questions