CODEWITHSUNDEEP
scheme
smk
smk

Reputation: 1

Can anyone please explain what is happening in this code?

This code in Scheme is used to output a list in which the element of the input lists are repeated n times. I do not understand what is happening in the code. 

(define (echo-lots lst n)
  (define (helper lst1 n1)
    (if (= n1 0)
        '()
        (cons lst1 (helper lst1 (- n1 1)))))
  (if (null? lst)
      '()
      (append (helper (car lst) n) (echo-lots (cdr lst) n)))

Upvotes: 0

Views: 53

Answers (1)

molbdnilo
molbdnilo

Reputation: 66371

First, note that helper does not use any of the parameters of echo-lots.
That means that you can move the definition outside and figure it out in isolation:

(define (helper lst1 n1)
    (if (= n1 0)
        '()
        (cons lst1 (helper lst1 (- n1 1)))))

> (helper 1 3)
'(1 1 1)
> (helper #f 4)
'(#f #f #f #f)
> (helper '(a b c) 2)
'((a b c) (a b c))

It makes a list whose elements are the first parameter repeated the number of times given by the second parameter.
(It's not difficult to prove this formally, if you're in the mood for that.)

Note also that the first parameter's name is misleading - it does not have to be a list.
Let's improve the naming:

(define (repeat item n)
    (if (= n 0)
        '()
        (cons item (repeat item (- n 1)))))

Now echo-lots is clearer:

(define (echo-lots lst n)
  (if (null? lst)
      '()
      (append (repeat (car lst) n) 
              (echo-lots (cdr lst) n))))

and it's easier to see that it makes a list of n copies of the first element of lst - (repeat (car lst) n) - and appends that to a list consisting of n copies of each of the remaining elements - (echo-lots (cdr lst) n).

Upvotes: 1

Related Questions