CODEWITHSUNDEEP
variablessassas-macroenterprise-guide
A_Pirates_Favorite_Letter
A_Pirates_Favorite_Letter

Reputation: 151

Running Things in Parallel with SAS Enterprise Guide

Good afternoon, Stack Overflow gods and goddesses. I have a question about running code in SAS Enterprise Guide 7.1 in parallel.

Currently, I have 5 small PROC SQLs running in a project. The code runs fine, but it executes in series (IE: One at a time) and even though I have each piece broken out in an individual section, I can't seem to get all 5 to run at once. For example, take the code below:

PROC SQL;
    connect to Oracle (user = "&Oracle_ID." password = "&Oracle_PW." path = "&Oracle_Path.");
    Create table place.base_balance_data as select * from connection to Oracle (
        Select 
            DEBR.Acct_Ref_Id
            ,case when DEBR.Acct_Typ_Cd = '2' and DEBR.Settle_Dt_Bal_Amt > 0
                then sum(settle_dt_bal_amt)
                else sum(0)
                end as Typ_2_Settle_Dt_Bal_Amt
            ,case when DEBR.Acct_Typ_Cd = '5' and DEBR.Settle_Dt_Bal_Amt > 0
                then sum(settle_dt_bal_amt)
                else sum(0)
                end as Typ_5_Settle_Dt_Bal_Amt
            ,case when DEBR.Acct_Typ_Cd = '1' and DEBR.Settle_Dt_Bal_Amt < 0
                then sum(settle_dt_bal_amt)
                else sum(0)
                end as Typ_1_Settle_Dt_Bal_Amt
            ,case when DEBR.Acct_Typ_Cd = '1' and DEBR.Settle_Dt_Bal_Amt < 0
                then sum(Csh_Free_Cr_Amt)
                else sum(0)
                end as Csh_Free_Cr_Amt
            ,case when DEBR.Acct_Typ_Cd = '1' and DEBR.Settle_Dt_Bal_Amt < 0
                then coalesce(DEBR.Cr_Avbl_Amt,0)
                end as Credit_Aval_Amt
        From Cool.DataStuff DEBR
        Where DEBR.Date_ID = &lm_bus_dID.
        Group by DEBR.Acct_Ref_Id, DEBR.Acct_Typ_Cd, DEBR.Cr_Avbl_Amt, DEBR.Settle_Dt_Bal_Amt
        Order by DEBR.Acct_Ref_ID asc offset 0 rows
    );
    Disconnect from Oracle;

Currently, the EG project looks like this: Current EG Process

I'm trying desperately to get all 5 of those pieces on the right to run at the same time, but alas, every time I try to do that, I get errors involving the passing of macro variables and not being able to connect to multiple sessions.

Has anyone had any luck doing this before? Could you maybe tell me what I'm missing here?

Thanks!

Upvotes: 1

Views: 1736

Answers (1)

Stu Sztukowski
Stu Sztukowski

Reputation: 12909

If you have SAS/CONNECT installed, you can break everything out into rsubmit blocks that will all run in parallel. You can ensure that each session gets the required macro vars using %syslput.

When running things in rsubmit blocks, think of each block as its own unique, independent worker session that's running code - almost like a thread. This worker lives in its own world and only knows what is in its session. The main session which kicked off the worker sessions is free to do whatever it pleases while the workers perform their specific tasks.

rsubmit

Below is an example of how to set this up.

Setup code

This will handle signing on to a metadata server in a new session automatically and make all code run asynchronously.

options autosignon=yes
        sascmd='!sascmd'
        connectwait=no
;

Create Macro Variables and pass them to your worker sessions

This will do two things:

  1. Start a new asynchronous session
  2. Send your macro variables from your main session to your worker session

..

<code to create macro vars>;

/* Send macro variables over to a new remote session */
%syslput mymacrovar / remote=worker1;
...

If you want to, you can use %syslput _USER_ / remote=worker1 to send all user-made macro variables to a new session.

Enclose all worker code in rsubmit blocks

libname workmain "%sysfunc(getoption(work))";

rsubmit remote=worker1 inheritlib=(<my libraries here> workmain);
    <code here>;
endrsubmit;

Note the libname statement, workmain. rsubmit cannot inherit the work library of the main session. This is by design since each of these sessions have their own work library whose name cannot be overwritten. You can get around it by creating a new library that points to your main session's work library.

Wait for everything to finish

Finally, you can add one last piece of code to wait for everything to finish up - or, you're free to have the main thread run more independent light tasks.

waitfor _ALL_;

Upvotes: 0

Related Questions