CODEWITHSUNDEEP
neo4jcypher
LdL
LdL

Reputation: 35

Loading sparse adjacency matrix on Neo4j

I'm trying to load a sparse (co-occurrence) matrix in Neo4j but after many failed queries, it's getting frustrating.

Raw data

Basically, I want to create the nodes from the ids, and the relationship weight against each other node (including itself) should be the value on the matrix.

So, for example, 'nhs' should have a self-relationship with weight 41 and 16 with 'england', and so on.

I was trying things like:

LOAD CSV WITH HEADERS FROM 'file:///matpharma.csv' AS row
MERGE (a: node{name: row.id})
MERGE (b: node{name: row.key})
MERGE (a)-[:w]-(b);

I'm not sure how to attach the edge values though (and not yet sure if the merges are producing the expected result).

Thanks in advance for the assistance

Upvotes: 0

Views: 706

Answers (2)

Christophe Willemsen
Christophe Willemsen

Reputation: 20185

This is a nice Cypher challenge :) Let's say that LOAD CSV is not really meant to do this and probably you would be happier by flattening your data

Here is what I came up with : 

LOAD CSV FROM "https://gist.githubusercontent.com/ikwattro/a5260d131f25bcce97c945cb97bc0bee/raw/4ce2b3421ad80ca946329a0be8a6e79ca025f253/data.csv" AS row
WITH collect(row) AS rows
WITH rows, rows[0] AS firstRow
UNWIND rows AS row
WITH firstRow, row SKIP 1
UNWIND range(0, size(row)-2) AS i
RETURN firstRow[i+1], row[0], row[i+1]

You can take a look at the gist

Upvotes: 0

InverseFalcon
InverseFalcon

Reputation: 30397

If you just need to add a property on a relationship, where the property value is in your CSV, then it's just a matter of adding a variable for the relationship that you MERGE in, and then using SET (or ON CREATE SET, if you only want to set the property if the relationship didn't exist and needed to be created). So something like:

LOAD CSV WITH HEADERS FROM 'file:///matpharma.csv' AS row
MERGE (a: node{name: row.id})
MERGE (b: node{name: row.key})
MERGE (a)-[r:w]-(b)
SET r.weight = row.weight

EDIT

Ah, took a look at the CSV clip. This is a very strange way to format your data. You have data in your header (that is, your headers are trying to define the other node to lookup) which is the wrong way to go about this. You should instead have, per row, one column that defines one of the two nodes to connect (like the "id" column) and then another column for the other node (something like an "id2"). That way you can just do two MATCHes to get your nodes, then a MERGE between them, and then setting the relationship property, similar to the sample query I provided above.

But if you're set on this format, then it's going to be a more complicated query, since we have to deal with dynamic access of the row keys and values.

Something like:

LOAD CSV WITH HEADERS FROM 'file:///matpharma.csv' AS row
MERGE (start:Node {name:row.id})
WITH start, row, [key in keys(row) WHERE key <> 'id'] as keys
FOREACH (key in keys | 
 MERGE (end:Node {name:key})
 MERGE (start)-[r:w]-(end)
 ON CREATE SET r.weight = row[key] )

Upvotes: 2

Related Questions