CODEWITHSUNDEEP
arraysperlreference
Marcin Cylke
Marcin Cylke

Reputation: 2066

Why do I get ARRAY(0x9c90818) instead of the items in the array in Perl?

I have two data structures in Perl:

An array:

my @array2 = ( "1", "2", "3");

for $elem (@array2) {
    print $elem."\n";
}

Giving me the following output:

1
2
3

And a list:

my @array = [ "1", "2", "3"];                                            

for $elem (@array) {
    print $elem."\n";
}

Giving the following output:

ARRAY(0x9c90818)

Obviously, I'd like to iterate over the elements in both cases, but why does the second solution give me only the reference to this array?

Upvotes: 50

Views: 60111

Answers (6)

Sandeep_black
Sandeep_black

Reputation: 1441

@array = ("1","2","3");

Here 1, 2, and 3 are the elements of the @array variable. $array[0] is 1, $array[1] is 2 and $array[2] is 3.

@array = ["1","2","3"];

Perl uses anonymous array references using [ ], so here basically only one element that you are storing, and that is the reference of an array ["1","2","3"] to the @array variable. for ex $array[0] is ARRAY(0x9c90818)

Hence while printing it is showing you the references.

Upvotes: 1

Lumi
Lumi

Reputation: 15284

If you want more clarification, see the relevant documentation.

You could try and do some things for illustration purposes:

#!perl -lw # -l appends a \n to each print, -w enables warnings
use strict;
my $aryref = [1 .. 5];
print for $aryref;    # Prints the stringified reference - not what you want
print for @$aryref;   # Dereferencing it lets you access the array
my @ary = $aryref;    # Probably not what you want
print for @ary;       # Stringified reference again
print for @{$ary[0]}; # Dereference the first array element (which holds the ref)

Upvotes: 4

ikegami
ikegami

Reputation: 386331

The square brackets create an anonymous array, populate the array with the contents of the brackets, and return a reference to that array. In other words,

[ "1", "2", "3" ]

is basically the same as

do { my @anon = ("1", "2", "3"); \@anon }

So the code should look like

my $array_ref = [ "1", "2", "3" ];

for (@$array_ref) {  # Short for @{ $array_ref }
    print "$_\n";
}

or

my @array_of_refs = ([ "1", "2", "3" ]);

for my $array_ref (@array_of_refs) {
    for (@$array_ref) {
        print "$_\n";
    }
}

Upvotes: 8

TLP
TLP

Reputation: 67900

The square brackets are used to create an anonymous array. When evaluated, it returns a reference to this array, not the actual array values.

Parentheses have no such hidden property, but simply override precedence inside expressions, much like in math. For example:

my @array = 1,2,3;

Is actually evaluated like this:

my @array = 1;
2,3; # causes the warning "Useless use of constant in void context"

because the = operator has higher precedence than the commas. So to get around that, we use parentheses when assigning arrays, like so:

my @array = (1,2,3);

Your example:

my @array = [1,2,3];

is somewhat like saying this:

my @tmp = (1,2,3);
my @array = \@tmp;

Where the \ is used to create a reference to the @tmp array.

Upvotes: 38

Eric Strom
Eric Strom

Reputation: 40152

Lists in Perl are not data structures, they are positions in the source code, determined by the context around them. Lists are basically the transient structures that Perl uses to move data around. You interact with them with all of Perl's syntax, but you can not work with them as a data type. The data type that is closest to a list is an array.

my @var    =    (1, 2, 3);  # parens needed for precedence, they do not create a list
   ^ an array    ^ a list

say 1, 2, 3;
    ^ a list

say @var;
    ^ a list (of one array, which will expand into 3 values before `say` is called)

When you write [1, 2, 3] what you are doing is creating a scalar array reference. That array reference is initialized with the list 1, 2, 3, and it is the same as creating a named array and taking a reference to it:

[1, 2, 3]   ~~   do {my @x = (1, 2, 3); \@x}

Since the [...] construct creates a scalar, you should hold it in a scalar:

my $array = [1, 2, 3];                                            

for my $elem (@$array) {   # lexical loop variable
    print $elem."\n";
}

Since you want to operate on the whole array, and not just the reference, you place a @ in front of the $array which dereferences the stored array reference.

Upvotes: 90

jwodder
jwodder

Reputation: 57590

In Perl, arrays and lists are essentially the same thing, but your second example uses neither. Square brackets surround an array reference (a scalar value), and "assigning" a scalar to an array with something like my @array = $scalar is equivalent to my @array = ($scalar). Thus, the only element of @array in your second example is an array reference.

Upvotes: 0

Related Questions