Reputation: 225
I've to write some transformation and calculation based on condition like count of cash/dd/cheque receipt and sum of cash/dd/cheque in the summary array. I've defined my input array and based on that i'm expecting the output that I've defined. Help me to complete the dataweave for that.\
Code:
%dw 2.0
output application/json
---
{
receipt: payload map ( payload01 , indexOfPayload01 ) -> {
receiptId: payload01.receiptId,
amountCollected: payload01.amountCollected,
paymentMode: payload01.paymentMode,
},
summary: {
TotalamountCollected: payload.*amountCollected reduce ((val, acc=0) -> acc + val)
}
}
input:
[{
"receiptId": 11000134453,
"amountCollected": 11,
"paymentMode": "Cash"
}, {
"receiptId": 1105444723,
"amountCollected": 12,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434763,
"amountCollected": 13,
"paymentMode": "DD"
},{
"receiptId": 11000134457,
"amountCollected": 14,
"paymentMode": "Cash"
}, {
"receiptId": 1105444728,
"amountCollected": 15,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434769,
"amountCollected": 16,
"paymentMode": "DD"
}]
output:
{
"summary": {
"TotalamountCollected": 81,
"cashRecepit": 2,
"cashRecepitAmount": 25,
"chequeRecepit": 2,
"chequeRecepitAmount": 27,
"ddRecepit": 2,
"ddRecepitAmount": 29
},
"receipt": [{
"receiptId": 11000134453,
"amountCollected": 11,
"paymentMode": "Cash"
}, {
"receiptId": 1105444723,
"amountCollected": 12,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434763,
"amountCollected": 13,
"paymentMode": "DD"
},{
"receiptId": 11000134457,
"amountCollected": 14,
"paymentMode": "Cash"
}, {
"receiptId": 1105444728,
"amountCollected": 15,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434769,
"amountCollected": 16,
"paymentMode": "DD"
}]
}
Help me to complete the dataweave for that.
Upvotes: 1
Views: 491
Reputation: 184
Here's another answer...Hope it helps
%dw 2.0
import * from dw::core::Arrays
import * from dw::core::Strings
output application/json
var inputJsonArr=[{
"receiptId": 11000134453,
"amountCollected": 11,
"paymentMode": "Cash"
}, {
"receiptId": 1105444723,
"amountCollected": 12,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434763,
"amountCollected": 13,
"paymentMode": "DD"
},{
"receiptId": 11000134457,
"amountCollected": 14,
"paymentMode": "Cash"
}, {
"receiptId": 1105444728,
"amountCollected": 15,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434769,
"amountCollected": 16,
"paymentMode": "DD"
}]
---
{
summary:{
'TotalamountCollected':inputJsonArr sumBy $.amountCollected,
'cashRecepit':inputJsonArr countBy (($.paymentMode) == 'Cash'),
'cashRecepitAmount':((inputJsonArr filter (value, index) -> ((value.paymentMode)== 'Cash'))sumBy $.amountCollected),
'chequeRecepit':inputJsonArr countBy (($.paymentMode) == 'Cheque'),
'chequeRecepitAmount':((inputJsonArr filter (value, index) -> ((value.paymentMode)== 'Cheque'))sumBy $.amountCollected),
'ddRecepit':inputJsonArr countBy (($.paymentMode) == 'DD'),
'ddRecepitAmount':((inputJsonArr filter (value, index) -> ((value.paymentMode)== 'DD'))sumBy $.amountCollected)
},
'receipt':inputJsonArr
}
Upvotes: 0
Reputation:
There are number of ways you can get it done.
1) Here's a flexible, process but not space efficient way you can get it done:
%dw 2.0
output application/dw
var data = [{
"receiptId": 11000134453,
"amountCollected": 11,
"paymentMode": "Cash"
}, {
"receiptId": 1105444723,
"amountCollected": 12,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434763,
"amountCollected": 13,
"paymentMode": "DD"
},{
"receiptId": 11000134457,
"amountCollected": 14,
"paymentMode": "Cash"
}, {
"receiptId": 1105444728,
"amountCollected": 15,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434769,
"amountCollected": 16,
"paymentMode": "DD"
}]
---
do {
var byPaymentMode = data groupBy $.paymentMode
---
{
summary: (byPaymentMode mapObject {
(lower($$) ++ "Receipt"): sizeOf($),
(lower($$) ++ "ReceiptAmount"): sum($.*amountCollected)
}),
receipt: data
}
}
2) Here's a not flexible, space but not process efficient way to get it done using the build-in dw::core::Arrays
module.
%dw 2.0
output application/dw
var data = [{
"receiptId": 11000134453,
"amountCollected": 11,
"paymentMode": "Cash"
}, {
"receiptId": 1105444723,
"amountCollected": 12,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434763,
"amountCollected": 13,
"paymentMode": "DD"
},{
"receiptId": 11000134457,
"amountCollected": 14,
"paymentMode": "Cash"
}, {
"receiptId": 1105444728,
"amountCollected": 15,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434769,
"amountCollected": 16,
"paymentMode": "DD"
}]
---
{
summary: {
TotalAmountCollected: data dw::core::Arrays::sumBy (e) -> e.amountCollected,
cashReceipt: data dw::core::Arrays::countBy (e) -> e.paymentMode == "Cash",
cashReceiptAmount: data dw::core::Arrays::sumBy (e) -> if (e.paymentMode == "Cash") e.amountCollected else 0,
checkReceipt: data dw::core::Arrays::countBy (e) -> e.paymentMode == "Cheque",
checkReceiptAmount: data dw::core::Arrays::sumBy (e) -> if (e.paymentMode == "Cheque") e.amountCollected else 0,
ddReceipt: data dw::core::Arrays::countBy (e) -> e.paymentMode == "DD",
ddReceiptAmount: data dw::core::Arrays::sumBy (e) -> if (e.paymentMode == "DD") e.amountCollected else 0
},
receipt: data
}
This last solution can also be made flexible quite easily so you do not hard-code the paymentMode
s.
Pick the one you like.
Upvotes: 6
Reputation: 1301
Here is a solution that involves one iteration over the input. I'm curious if anyone has any cleaner solutions.
%dw 2.0
output application/json
var inputVar =
[{
"receiptId": 11000134453,
"amountCollected": 11,
"paymentMode": "Cash"
}, {
"receiptId": 1105444723,
"amountCollected": 12,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434763,
"amountCollected": 13,
"paymentMode": "DD"
},{
"receiptId": 11000134457,
"amountCollected": 14,
"paymentMode": "Cash"
}, {
"receiptId": 1105444728,
"amountCollected": 15,
"paymentMode": "Cheque"
}, {
"receiptId": 1143434769,
"amountCollected": 16,
"paymentMode": "DD"
}]
var init =
{
"TotalamountCollected": 0,
"cashRecepit": 0,
"cashRecepitAmount": 0,
"chequeRecepit": 0,
"chequeRecepitAmount": 0,
"ddRecepit": 0,
"ddRecepitAmount": 0
}
fun calcModeAmmount(acc, isTargetedMode, addend) = acc + if(isTargetedMode) addend else 0
fun summary() = inputVar reduce(item, acc=init) ->
{
"TotalamountCollected": acc.TotalamountCollected + item.amountCollected,
"cashRecepit": calcModeAmmount(acc.cashRecepit, item.paymentMode == "Cash", 1),
"cashRecepitAmount": calcModeAmmount(acc.cashRecepitAmount, item.paymentMode == "Cash", item.amountCollected),
"chequeRecepit": calcModeAmmount(acc.chequeRecepit, item.paymentMode == "Cheque", 1),
"chequeRecepitAmount": calcModeAmmount(acc.chequeRecepitAmount, item.paymentMode == "Cheque", item.amountCollected),
"ddRecepit": calcModeAmmount(acc.ddRecepit, item.paymentMode == "DD", 1),
"ddRecepitAmount": calcModeAmmount(acc.ddRecepitAmount, item.paymentMode == "DD", item.amountCollected)
}
---
{
summary:summary(),
receipt:inputVar
}
Upvotes: 3