CODEWITHSUNDEEP
perlscripting
fenec
fenec

Reputation: 5806

how can i generate list of dates in perl?

I want to write a script that generates dates between now and the last year in perl.

Ex 

                <option value="01/02/2010">Feb 07</option>
                <option value="01/03/2010">Mar 07</option>
                <option value="01/04/2010">Apr 07</option>
                <option value="01/05/2010">May 07</option>
                <option value="01/06/2010">Jun 07</option>
                <option value="01/07/2010">Jul 07</option>
                <option value="01/08/2010">Aug 07</option>
                <option value="01/09/2010">Sep 07</option>
                <option value="01/10/2010">Oct 07</option>
                <option value="01/11/2010">Nov 07</option>
                <option value="01/12/2010">Dec 07</option

I have no idea how I can do it. I am doing it manually for now

Upvotes: 1

Views: 3451

Answers (5)

Cooper
Cooper

Reputation: 679

Another module worth looking into is Date::Calc. I needed a module to replace some awkward date calculations for one of my scripts and it looks like it does anything I'd ever need it to do. http://metacpan.org/pod/Date::Calc

Upvotes: 0

Chris Charley
Chris Charley

Reputation: 6598

Using Date::Simple

#!/usr/bin/perl
use strict;
use warnings;
use 5.012;
use Date::Simple qw/ today ymd /;

my $now = today;

for (my $date = ymd($now->year, 1, 1); $date <= $now; $date++) {
    say $date;  
}

If you want last year (not beginning of this year) you could call 'ymd' in the loop as:

ymd($now->year()-1, 1, 1);

Upvotes: 0

Axeman
Axeman

Reputation: 29854

use 5.010;
use strict;
use warnings;

use POSIX qw<strftime>;

my @loc = localtime();

for ( 1..12 ) { 
    say strftime( qq{<option value="01/%m/%Y">%b 07</option>}, @loc );
    $loc[4]--;
}

Output:

<option value="01/05/2011">May 07</option>
<option value="01/04/2011">Apr 07</option>
<option value="01/03/2011">Mar 07</option>
<option value="01/02/2011">Feb 07</option>
<option value="01/01/2011">Jan 07</option>
<option value="01/12/2010">Dec 07</option>
<option value="01/11/2010">Nov 07</option>
<option value="01/10/2010">Oct 07</option>
<option value="01/09/2010">Sep 07</option>
<option value="01/08/2010">Aug 07</option>
<option value="01/07/2010">Jul 07</option>
<option value="01/06/2010">Jun 07</option>

Just for grins, alternative compressed version:

use 5.010;
use strict;
use warnings;

use POSIX qw<strftime>;

say join( "\n"
        , map { 
             my $t = strftime( qq{<option value="01/%m/%Y">%b 07</option>}, @$_ ); 
             $_->[4]--; 
             $t; 
          }
          (( [ localtime ] ) x 12 )
       );

Upvotes: 0

shawnhcorey
shawnhcorey

Reputation: 3601

Try:

#!/usr/bin/env perl

use strict;
use warnings;

use POSIX;

my $Now = time;
my @Now = localtime( $Now );

for my $count ( 1 .. 12 ){
  # month/day/year
  print strftime( "%m/%d/%Y\n", @Now );
  $Now[4] --;
  if( $Now[4] < 0 ){
    $Now[4] = 11;
    $Now[5] --;
  }
}

Upvotes: 2

Quentin
Quentin

Reputation: 943615

Adjust formatting and amount subtracted for taste.

#!/usr/bin/perl

use strict;
use warnings;
use DateTime;

my $now = DateTime->now;
my $start_of_last_year = DateTime->new( year => $now->year - 1 );
while ( $now > $start_of_last_year ) {
        print $now->ymd('/'), "\n";
        $now->subtract( days => 1 );
}

Upvotes: 6

Related Questions