CODEWITHSUNDEEP
functionvariablesactionscript-3reference
Jyreeil
Jyreeil

Reputation: 75

Pass Variables As Reference AS3

I have a function which has arguments that will modify multiple variables that are global. And I want the arguments to be reference arguments, so they can modify multiple global variables with the same lines of code that are modifying the arguments.

example(psuedocode):

function random(a:number, b:number, c:number):void{
a = RNG(20);
b = RNG(25);
c = RNG(30);
}

there will be two different variables passed in through a, b and c, these are global, but a, b and c are not. The goal is to not have to have identical lines of code for both separate sets of variables to set the RNG numbers.

Edit: So I suppose more explanation is in order I will probably just try to research making a wrapper or other object to add all the variables to, but I just didn't know what type of object to make and how to make it. I admit I was just being a little bit lazy in a little bit too complex creative way.

I have two sets of global variables that I want to pass into this function and set them equal to the same range of RNG as the corresponding ones in each set. The way I'm trying to do this without repeating "a = RNG(20);" twice for each one is by passing the global variables into the function as arguments, but the arguments are the variables that are having the RNG set to them. The only way this can work is if the variables are passed to the function as reference so that setting the RNG to the arguments will change the global variables.

Upvotes: 1

Views: 315

Answers (1)

Organis
Organis

Reputation: 7316

There are two types of data in AS3:

  1. Plain data: Boolean, String, Number, int, uint — always passed as values.
  2. Objects: Object, Array and literally everything else — always passed as a pointer/reference rather than through copy/clone.

There's no trick, like in C/C++ there is, to pass some plain variable as a pointer to let a method modify the original and only value.

That said, there are two ways around.

Solution №1: you can pass variables indirectly, in pairs like container → variable name.

function doIt(A:Object, a:String):void
{
    A[a] = RNG(20);
}

Solution №2: devise a custom wrapper class to cross the border between plain and object data.

Implementation:

package
{
    public class Oint
    {
        public var data:int;

        // Class constructor.
        public function Oint(value:int = 0)
        {
            data = value;
        }

        // There's always nice to have a interface methods,
        // rather than member or getter/setter, because
        // you can actually link to read/write methods.
        public function read():int
        {
            return data;
        }

        public function write(value:int):void
        {
            data = value;
        }

        // With this you can use Oint variables in math expressions.
        public function valueOf():Object
        {
            return data;
        }

        // With this you can trace Oint variables and see their values.
        public function toString():String
        {
            return data.toString();
        }
    }
}

Usage:

function random(a:Oint, b:Oint, c:Oint):void
{
    a.data = RNG(20);
    b.data = RNG(25);
    c.data = RNG(30);
}

Upvotes: 3

Related Questions