CODEWITHSUNDEEP
excel
SkysLastChance
SkysLastChance

Reputation: 221

Grab header name of all max values

So I have a formula that finds the max value in a row and grabs the header name of the column.

The problem is if I have a row with 2 of the the same max value it only grabs the name of the first one.

Is it possible to grab all headers with the same max value with a formula?

Here is what I am using. 

=INDEX(Header,0,MATCH(MAX($D2:$BV2),$D2:$BV2,0))

Upvotes: 0

Views: 51

Answers (1)

Scott Craner
Scott Craner

Reputation: 152660

To return the list in one cell, if one has the Dynamic Array formulas:

=TEXTJOIN(", ",,FILTER(Header,MAX($D2:$BV2)=$D2:$BV2))

If one does not have the Dynamic Array formula then we need to use VBA. There are many TEXTJOIN UDF's out there. Here is mine:

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function

Then one would call it using:

=TEXTJOIN(", ",TRUE,IF(MAX($D2:$BV2)=$D2:$BV2,Header,""))

And confirm it as an array formula with Ctrl-Shift-Enter instead of Enter when exiting edit mode.

Upvotes: 2

Related Questions