Sending email message with attachment by powershell with a batch file

Question

Hi i'm trying to send email from batch file.bat but I'm getting a list of red errors and rolling really fast and the window close also fast I tried to keep it open by the command

cmd /k

and it's still open but it won't show any error list.

not that: I'm using Gmail account as smtp and i opened smtp settings and enabled the less secure login option.

finally what to run the bat is that command. cmd execute command :

file.bat "mygmail@gmail.com" "mypassword" "D:\test\myFile.txt"

file.bat contains :

@ECHO OFF
    SET GmailAccount=%~1
    SET GmailPassword=%~2
    SET Attachment=%~3

    CALL :PowerShell
    CD /D "%PowerShellDir%"
    Powershell -ExecutionPolicy Bypass -Command "& '%PSScript%' '%GmailAccount%' '%GmailPassword%' '%Attachment%'"
    EXIT

    :PowerShell
    SET PowerShellDir=C:\Windows\System32\WindowsPowerShell\v1.0
    SET PSScript=%temp%\~tmpSendeMail.ps1
    IF EXIST "%PSScript%" DEL /Q /F "%PSScript%"

    ECHO $Username      = $args[0]>> "%PSScript%"
    ECHO $EmailPassword = $args[1]>> "%PSScript%"
    ECHO $Attachment    = $args[2]>> "%PSScript%"
    ECHO                          >> "%PSScript%"
    ECHO $Username    = $Username                 >> "%PSScript%"
    ECHO $EmailTo     = "target@mail.com" >> "%PSScript%"
    ECHO $EmailFrom   = "mygmail@gmail.com" >> "%PSScript%"
    ECHO $Subject     = "test"           >> "%PSScript%"
    ECHO $Body        = "test"              >> "%PSScript%"
    ECHO $SMTPServer  = "smtp.gmail.com"          >> "%PSScript%"
    ECHO $SMTPMessage = New-Object System.Net.Mail.MailMessage($EmailFrom, $EmailTo, $Subject, $Body) >> "%PSScript%"
    ECHO $Attachment  = New-Object System.Net.Mail.Attachment($Attachment)                            >> "%PSScript%"
    ECHO $SMTPMessage.Attachments.Add($Attachment)                                                    >> "%PSScript%"
    ECHO $SMTPClient = New-Object Net.Mail.SmtpClient($SmtpServer, 587)                               >> "%PSScript%"
    ECHO $SMTPClient.EnableSsl = $true                                                                >> "%PSScript%"
    ECHO $SMTPClient.Credentials = New-Object System.Net.NetworkCredential($Username, $EmailPassword) >> "%PSScript%"
    ECHO $SMTPClient.Send($SMTPMessage)     

please Help me what is the problem here. Thanks.

Answer 1

First of all : This is a reminder for how to use less secure applications with google accounts

PS-Gmail-Sender.bat

@ECHO OFF
REM https://stackoverflow.com/questions/28605803/can-not-send-mail-using-smtp-gmail-com-port-587-from-vbs-script/28606754#28606754
Title Sending E-Mail with Gmail Less Secure Applications using Powershell and Batch
SET GmailAccount="%~1"
SET GmailPassword="%~2"
SET Attachment="%~3"
REM We write our Powershell script 
CALL :WritePS
REM We execute our Powershell script .PS1 by passing arguments from the command line or a batch file
Powershell -ExecutionPolicy bypass -noprofile -file "%PSScript%" "%GmailAccount%" "%GmailPassword%" "%Attachment%"
IF EXIST "%PSScript%" DEL /Q /F "%PSScript%"
pause
EXIT
REM -----------------------------------------------------------------------------------------------------
:WritePS
SET PSScript=%temp%\temp_SendeMail.ps1
> "%PSScript%" (
    ECHO $Username  = $args[0]
    ECHO $EmailPassword = $args[1]
    ECHO $Attachment= $args[2]
    ECHO $EmailTo = $Username
    ECHO $EmailFrom  = $Username
    ECHO $Subject = "This email was sent from Powershell script into a batch file with Less Secure Application Enabled"   
    ECHO $Body= "Test Email Sending with a script"  
    ECHO $SMTPServer  = "smtp.gmail.com"  
    ECHO $SMTPMessage = New-Object System.Net.Mail.MailMessage($EmailFrom, $EmailTo, $Subject, $Body^) 
    ECHO $Attachment  = New-Object System.Net.Mail.Attachment($Attachment^)
    ECHO $SMTPMessage.Attachments.Add($Attachment^)
    ECHO $SMTPClient = New-Object Net.Mail.SmtpClient($SmtpServer, 587^)
    ECHO $SMTPClient.EnableSsl = $true
    ECHO $SMTPClient.Credentials = New-Object System.Net.NetworkCredential($Username, $EmailPassword^) 
    ECHO $SMTPClient.Send($SMTPMessage^)
)
Exit /B
REM -----------------------------------------------------------------------------------------------------

So with the command line or a batch file we can call it as below :

PS-Gmail-Sender.bat "Mygmail_Account@gmail.com" "MyGmail_Password" "D:\test\myFile.txt"