CODEWITHSUNDEEP
wolfram-mathematicamathematica-frontend
Alexey Popkov
Alexey Popkov

Reputation: 9425

TableForm with TableHeadings aligned to Left but the content of table aligned to Right

TableForm with TableHeadings option is a quick and easy way to display good-looking classical table in Mathematica FrontEnd. The only problem is that it is common to display such a table with headings aligned to the left but the content of the table aligned to the right. Is it possible to force TableForm to behave in this way? Or if not, what is the best way to make an analog of TableForm that behaves in this way?

Upvotes: 4

Views: 1342

Answers (3)

Alexey Popkov
Alexey Popkov

Reputation: 9425

It appears that one way to do this is:

RawBoxes[ToBoxes[
   TableForm[RandomReal[{-10, 10}, {3, 3}], 
    TableHeadings -> {{"First left header", "Second left header", 
       "Trird left header"}, {"First top header", "Second top header",
        "Third top header"}}]] /. (ColumnAlignments -> _) -> 
   ColumnAlignments -> {Left, Right}]

One can make such behavior permanent using Villegas-Gayley trick:

Unprotect[TableForm];
TableForm[args___] /; ! TrueQ@$inTableForm := 
 Block[{$inTableForm = True}, 
  RawBoxes[ToBoxes[TableForm[args]] /. (ColumnAlignments -> _) -> 
     ColumnAlignments -> {Left, Right}]]
Protect[TableForm];

Now

TableForm[RandomReal[{-10, 10}, {3, 3}], 
 TableHeadings -> {{"First left header", "Second left header", 
    "Third left header"}, {"First top header", "Second top header", 
    "Third top header"}}]

gives:

Modified TableForm

Another way is to define alternative function myTableForm:

myTableForm[args___] := 
 RawBoxes[ToBoxes[TableForm[args]] /. (ColumnAlignments -> _) -> 
    ColumnAlignments -> {Left, {Right}}]

Upvotes: 2

Mr.Wizard
Mr.Wizard

Reputation: 24336

You can use Grid and Alignment. Here is one way:

a = Map[Mod[RandomInteger[2*^9], 10^#] &, RandomInteger[{1, 6}, {4, 7}], {2}];

b = Item[#, Alignment -> Left] & /@
      {"One", "Two", "Three", "Four", "Five", "Six", "Seven"};

Grid[a~Prepend~b, Alignment -> Right]

Here is another:

headings = {"One", "Two", "Three", "Four", "Five", "Six", "Seven"};

Grid[a ~Prepend~ headings,
     Dividers -> {None, {2 -> True}}, 
     Alignment -> {Right, Automatic, {{1, 1}, {1, -1}} -> Left}
]

enter image description here

Upvotes: 3

Codie CodeMonkey
Codie CodeMonkey

Reputation: 7946

You can get far more control using Grid or GridBox if TableForm doesn't do what you like.

Upvotes: 1

Related Questions