CODEWITHSUNDEEP
amazon-web-servicesterraformterraform0.12+
Marshallm
Marshallm

Reputation: 1165

Iterate through list of dictionaries to create terraform resources with different values

Goal Create two aws_athena_named_query resources using terraform. The configuration for each query is defined in separate dictionaries. All of the query dictionaries are nested in a list (see query_dict variable).

variable query_dict {
    default = [
        {
            name = "query1"
            workgroup = "bar"
            query = "SELECT * FROM foo"   
        },
        {
            name = "query2"
            workgroup = "bar"
            query = "SELECT * FROM baz"   
        }
    ]
}

resource "aws_athena_named_query" "olap" {
  for_each = toset([for query in var.query_dict: {
            name   = query.name
            workgroup = query.workgroup
            query = query.query}])
  name = each.value.name
  query = each.value.query
  database = "test"
  workgroup = each.value.workgroup
}

Which results in the error:

The given "for_each" argument value is unsuitable: "for_each" supports maps
and sets of strings, but you have provided a set containing type object.

Attempt 2:

resource "aws_athena_named_query" "olap" {
  for_each = [for query in tomap(var.query_dict): {
            name   = query.name
            workgroup = query.workgroup
            query = query.query}]
  name = each.value.name
  query = each.value.query
  database = "test"
  workgroup = each.value.workgroup
}

Which results in:

Invalid value for "v" parameter: cannot convert tuple to map of any single
type.

Attempt 3:

resource "aws_athena_named_query" "olap" {
  count = length(var.query_dict)
  name = query_dict[count.index]["name"]
  query = query_dict[count.index]["query"]
  database = "test"
  workgroup = query_dict[count.index]["workgroup"]
}

Which outputs the error:

  on main.tf line 57, in resource "aws_athena_named_query" "olap":
  57:   workgroup = query_dict[count.index]["workgroup"]

A reference to a resource type must be followed by at least one attribute
access, specifying the resource name.

Expected Output:

# aws_athena_named_query.olap["query1"] will be created
  + resource "aws_athena_named_query" "olap" {
      + database  = "db"
      + id        = (known after apply)
      + name      = "query1"
      + query     = "SELECT * FROM foo"
      + workgroup = "bar"
    }

# aws_athena_named_query.olap["query2"] will be created
  + resource "aws_athena_named_query" "olap" {
      + database  = "db"
      + id        = (known after apply)
      + name      = "query2"
      + query     = "SELECT * FROM baz"
      + workgroup = "bar"
    }

Upvotes: 1

Views: 13418

Answers (2)

Parsifal
Parsifal

Reputation: 4486

There's no need to use for_each in this case, because you're actually iterating a list. You can use count:

resource "aws_athena_named_query" "olap" {
  count = length(var.query_dict)
  name = var.query_dict[count.index]['name']
  query = var.query_dict[count.index]['query']
  database = "test"
  workgroup = var.query_dict[count.index]['workgroup']
}

Upvotes: 3

Marcin
Marcin

Reputation: 238209

I think the following should work:

resource "aws_athena_named_query" "olap" {

  for_each = {for idx, query in var.query_dict: idx => query}
  
  name = each.value.name
  query = each.value.query
  database = "test"
  workgroup = each.value.workgroup
}

In the above you create map with idx as a key:

{
  "0" = {
    "name" = "query1"
    "query" = "SELECT * FROM foo"
    "workgroup" = "bar"
  }
  "1" = {
    "name" = "query2"
    "query" = "SELECT * FROM baz"
    "workgroup" = "bar"
  }
}

Upvotes: 7

Related Questions