CODEWITHSUNDEEP
julia
Sergei
Sergei

Reputation: 71

Problems with ODE solving

I'm trying to solve typical example from the DifferentialEquation package, according to the guide from their page.

Here is the example:

using DifferentialEquations
using Plots

function lorenz(t,u, du)
    du[1] = 10.0(u[2]-u[1])
    du[2] = u[1]*(28.0-u[3]) - u[2]
    du[3] = u[1]*u[2] - (8/3)*u[3]
end
   
u0 = [1.0;0.0;0.0]
tspan = (0.0,100.0)
prob = ODEProblem(lorenz,u0,tspan)
sol = solve(prob)
plot(sol,vars=(1,2,3))

Then I get:

ERROR: LoadError: Parameters were indexed but the parameters are nothing. You likely forgot to pass in parameters to the DEProblem!

What is wrong here? Thanks in advance!

Upvotes: 6

Views: 440

Answers (1)

Serge de Gosson de Varennes
Serge de Gosson de Varennes

Reputation: 11504

You could try to follow this example which builds on what you've done:

using DifferentialEquations
using Plots

function lorenz(du,u,p,t)
 du[1] = p[1]*(u[2]-u[1])
 du[2] = u[1]*(p[2]-u[3]) - u[2]
 du[3] = u[1]*u[2] - p[3]*u[3]
end

u0 = [1.0;0.0;0.0]
tspan = (0.0,100.0)
p = (10.0,28.0,8/3)
prob = ODEProblem(lorenz, u0, tspan,p)
sol = solve(prob)
xyzt = plot(sol, plotdensity=10000,lw=1.5)
xy = plot(sol, plotdensity=10000, vars=(1,2))
xz = plot(sol, plotdensity=10000, vars=(1,3))
yz = plot(sol, plotdensity=10000, vars=(2,3))
xyz = plot(sol, plotdensity=10000, vars=(1,2,3))
plot(plot(xyzt,xyz),plot(xy, xz, yz, layout=(1,3),w=1), layout=(2,1))

Upvotes: 2

Related Questions