How to properly add a Event Handler to the EventHandlerList of a Control?

Question

I'm trying to write a class whose constructor expects a reference to a control / component, and the name of an event within the control class. The purpose is to dynamically subscribe to the specified event from the instance of the referenced control by adding a event handler at run-time:

Public NotInheritable Class ExampleType(Of T As Component)

    Public ReadOnly Property Target As T

    Public Sub New(target As T, eventName As String)
        Me.Target = target

        Dim eventsProperty As PropertyInfo = 
            GetType(Component).GetProperty("Events", 
                                           BindingFlags.DeclaredOnly Or 
                                           BindingFlags.ExactBinding Or 
                                           BindingFlags.Instance Or 
                                           BindingFlags.NonPublic, 
                                           Type.DefaultBinder, 
                                           GetType(EventHandlerList), 
                                           Type.EmptyTypes, Nothing)
      
        Dim eventHandlerList As EventHandlerList = 
            DirectCast(eventsProperty.GetValue(target, BindingFlags.Default, 
                                               Type.DefaultBinder, Nothing, 
                                               CultureInfo.InvariantCulture), 
                                               EventHandlerList)

        Dim eventHandler As New EventHandler(AddressOf Me.Target_Handler)
        eventHandlerList.AddHandler(eventName, eventHandler)
    End Sub

    Private Sub Target_Handler(sender As Object, e As EventArgs)
        Console.WriteLine("Test")
    End Sub

End Class

Example usage:

Dim target As NumericUpDown = Me.NumericUpDown1
Dim eventName As String = NameOf(NumericUpDown.ValueChanged)

Dim example As New ExampleType(Of NumericUpDown)(target, eventName)

The problem is that in the example above the Target_Handler method is never reached when in this case the Me.NumericUpDown1.ValueChanged event is raised, unless I invoke the event handler method from code (with: eventHandlerList(eventName).DynamicInvoke(target, Nothing))

What I'm doing wrong?, how to solve my problem?. Thanks in advance.

Jimi · Accepted Answer

I think this method can be simplified getting the EventInfo object from the Component instance Type, using the GetEvent() method, then adding a new Delegate, using the EventInfo.AddEventHandler() method, passing the delegate type returned by the the EventInfo object itself, in the EventInfo.EventHandlerType property (defined the Event Handler Type this event uses).

The AddEventHandler() method wants the Type Instance to which the new Event delegate is added and a Delegate object: this Delegate can be created using the Delegate.CreateDelegate method, which accepts a handler method as a string.
The Target type is the class Instance where the Delegate is defined, so the current Instance of your ExampleType class.

Something like this should do:
_{No Exceptions are handled here: verify at least whether .GetEvent(eventName) returns null}

Imports System.ComponentModel
Imports System.Reflection

Public NotInheritable Class ExampleType(Of T As Component)

    Public ReadOnly Property Target As T

    Public Sub New(target As T, eventName As String)
        Me.Target = target

        Dim eventNfo = target.GetType().GetEvent(eventName)
        ' Or
        ' Dim eventNfo = GetType(T).GetEvent(eventName)

        eventNfo.AddEventHandler(target, [Delegate].CreateDelegate(
            eventNfo.EventHandlerType, Me, NameOf(Me.Target_Handler))
       ' Or
       ' eventNfo.AddEventHandler(Target, New EventHandler(AddressOf Target_Handler))
    End Sub

    Private Sub Target_Handler(sender As Object, e As EventArgs)
        Console.WriteLine("Test")
    End Sub
End Class

Alternative method to handle a local (static) EventHandlerList:

Public NotInheritable Class ExampleType(Of T As Component)
    Implements IDisposable

    Private Shared m_EventList As EventHandlerList = New EventHandlerList()
    Private m_Delegate As [Delegate] = Nothing
    Private m_Event As Object = Nothing

    Public Sub New(target As T, eventName As String)
        Me.Target = target
        AddEventHandler(eventName)
    End Sub

    Public ReadOnly Property Target As T

    Private Sub AddEventHandler(eventName As String)
        m_Event = eventName
        Dim eventNfo = Target.GetType().GetEvent(eventName)
        m_Delegate = [Delegate].CreateDelegate(eventNfo.EventHandlerType, Me, NameOf(Me.Target_Handler))
        m_EventList.AddHandler(m_Event, m_Delegate)
        eventNfo.AddEventHandler(Target, m_EventList(m_Event))
    End Sub

    Private Sub RemoveEventHandler()
        Dim eventNfo = Target.GetType().GetEvent(m_Event.ToString())
        eventNfo?.RemoveEventHandler(Target, m_EventList(m_Event))
        m_EventList.RemoveHandler(m_Event, m_Delegate)
        m_Delegate = Nothing
    End Sub

    Private Sub Target_Handler(sender As Object, e As EventArgs)
        Console.WriteLine("Test")
    End Sub

    Public Sub Dispose() Implements IDisposable.Dispose
        Dispose(True)
        GC.SuppressFinalize(Me)
    End Sub
    Public Sub Dispose(disposing As Boolean)
        If disposing AndAlso m_Delegate IsNot Nothing Then
            RemoveEventHandler()
        End If
    End Sub
End Class

The you can have:

Private example As ExampleType(Of Component)
Private example2 As ExampleType(Of Component)

' [...]

example = New ExampleType(Of Component)(Me.NumericUpDown1, NameOf(NumericUpDown.ValueChanged))
example2 = New ExampleType(Of Component)(Me.TextBox1, NameOf(TextBox.TextChanged))

Then call Dispose() on each object (or a List of these objects) to remove the handler and clean up the local EventHandlerList. The EventHandlerList relative to each Component can be accessed via reflection, but, as mentioned, won't contain ListEntry objects of all event delegates of a Control.

example.Dispose()
example2.Dispose()

How to properly add a Event Handler to the EventHandlerList of a Control?

Answers (2)

Related Questions