How can I fix an unresolved external symbol _DllMainCRTStartup when building a dll with scons?

Question

EDIT: Turned out to be user error. My scource isn't in NativeLib/, it's in NativeLib/NativeLib/. Always check your paths!

I am trying to build a dll with visual studio community 2019 and scons 4.1.0 and I am getting an unresolved external symbol.

E:\Projects\GodotProjects\Units\Units>scons -c platform=windows
scons: Reading SConscript files ...
scons: done reading SConscript files.
scons: Cleaning targets ...
scons: done cleaning targets.

E:\Projects\GodotProjects\Units\Units>scons platform=windows
scons: Reading SConscript files ...
scons: done reading SConscript files.
scons: Building targets ...
link /nologo /dll /out:Godot\bin\win64\libgdexample.dll /implib:Godot\bin\win64\libgdexample.lib /LIBPATH:E:\Projects\GodotProjects\Units\godot-cpp\bin libgodot-cpp.windows.debug.64.lib
LINK : warning LNK4001: no object files specified; libraries used
LINK : warning LNK4068: /MACHINE not specified; defaulting to X64
LINK : error LNK2001: unresolved external symbol _DllMainCRTStartup
Godot\bin\win64\libgdexample.dll : fatal error LNK1120: 1 unresolved externals
scons: *** [Godot\bin\win64\libgdexample.dll] Error 1120
scons: building terminated because of errors.

According to the docs (DLLs and Visual C++ run-time library behavior), "When you build a Dynamic-link Library (DLL) by using Visual Studio, by default, the linker includes the Visual C++ run-time library (VCRuntime). ... When linked into a DLL, the VCRuntime code provides an internal DLL entry-point function called _DllMainCRTStartup that handles Windows OS messages to the DLL to attach to or detach from a process or thread."

So it sounds like I need to include VCRuntime somehow, but I can't find a library for it. Acording to this, _DllMainCRTStartup is in corelibc.lib but I can't find any information on where to find or how to include it.

I also have no idea where the reference to _DllMainCRTStartup even is. It's not in any of my .cpp or .h files and I couldn't find it in the sconstruct file or any visual studio files. I don't think I know enough about compilers yet to debug this any further.

Here is my SConstruct file:

#!python
import os, subprocess

opts = Variables([], ARGUMENTS)

# Gets the standard flags CC, CCX, etc.

# env = DefaultEnvironment()    - changed at request of bdbaddog
env = Environment()

# Define our options
opts.Add(EnumVariable('target', "Compilation target", 'debug', ['d', 'debug', 'r', 'release']))
opts.Add(EnumVariable('platform', "Compilation platform", '', ['', 'windows', 'x11', 'linux', 'osx']))
opts.Add(EnumVariable('p', "Compilation target, alias for 'platform'", '', ['', 'windows', 'x11', 'linux', 'osx']))
opts.Add(BoolVariable('use_llvm', "Use the LLVM / Clang compiler", 'no'))
opts.Add(PathVariable('target_path', 'The path where the lib is installed.', 'Godot/bin/'))
opts.Add(PathVariable('target_name', 'The library name.', 'libgdexample', PathVariable.PathAccept))

# Local dependency paths, adapt them to your setup
godot_headers_path = "../godot-cpp/godot-headers/"
cpp_bindings_path = "../godot-cpp/"
cpp_library = "libgodot-cpp"

# only support 64 at this time..
bits = 64

# Updates the environment with the option variables.
opts.Update(env)

# Process some arguments
if env['use_llvm']:
    env['CC'] = 'clang'
    env['CXX'] = 'clang++'

if env['p'] != '':
    env['platform'] = env['p']

if env['platform'] == '':
    print("No valid target platform selected.")
    quit();

# Check our platform specifics
if env['platform'] == "osx":
    env['target_path'] += 'osx/'
    cpp_library += '.osx'
    if env['target'] in ('debug', 'd'):
        env.Append(CCFLAGS = ['-g','-O2', '-arch', 'x86_64', '-std=c++17'])
        env.Append(LINKFLAGS = ['-arch', 'x86_64'])
    else:
        env.Append(CCFLAGS = ['-g','-O3', '-arch', 'x86_64', '-std=c++17'])
        env.Append(LINKFLAGS = ['-arch', 'x86_64'])

elif env['platform'] in ('x11', 'linux'):
    env['target_path'] += 'x11/'
    cpp_library += '.linux'
    if env['target'] in ('debug', 'd'):
        env.Append(CCFLAGS = ['-fPIC', '-g3','-Og', '-std=c++17'])
    else:
        env.Append(CCFLAGS = ['-fPIC', '-g','-O3', '-std=c++17'])

elif env['platform'] == "windows":
    env['target_path'] += 'win64/'
    cpp_library += '.windows'
    # This makes sure to keep the session environment variables on windows,
    # that way you can run scons in a vs 2017 prompt and it will find all the required tools
    # env.Append(ENV = os.environ)

    #env.Append(CCFLAGS = ['-DWIN32', '-D_WIN32', '-D_WINDOWS', '-W3', '-GR', '-D_CRT_SECURE_NO_WARNINGS'])    - changed at request of bdbaddog
    env.Append(CCFLAGS = ['-D_WIN32', '-D_WINDOWS', '-W3', '-GR', '-D_CRT_SECURE_NO_WARNINGS'])
    env.Append(CPPDEFINES = ['WIN32'])
    
    if env['target'] in ('debug', 'd'):
        env.Append(CCFLAGS = ['-EHsc', '-D_DEBUG', '-MDd'])
    else:
        env.Append(CCFLAGS = ['-O2', '-EHsc', '-DNDEBUG', '-MD'])

if env['target'] in ('debug', 'd'):
    cpp_library += '.debug'
else:
    cpp_library += '.release'

cpp_library += '.' + str(bits)

# make sure our binding library is properly includes
env.Append(CPPPATH=['.', godot_headers_path, cpp_bindings_path + 'include/', cpp_bindings_path + 'include/core/', cpp_bindings_path + 'include/gen/'])
env.Append(LIBPATH=[cpp_bindings_path + 'bin/'])
env.Append(LIBS=[cpp_library])

# tweak this if you want to use different folders, or more folders, to store your source code in.
env.Append(CPPPATH=['NativeLib/'])
sources = Glob('NativeLib/*.cpp')

library = env.SharedLibrary(target=env['target_path'] + env['target_name'] , source=sources)

Default(library)

# Generates help for the -h scons option.
Help(opts.GenerateHelpText(env))

Answer 1

From this line

link /nologo /dll /out:Godot\bin\win64\libgdexample.dll /implib:Godot\bin\win64\libgdexample.lib /LIBPATH:E:\Projects\GodotProjects\Units\godot-cpp\bin libgodot-cpp.windows.debug.64.lib

I can see that you're still not compiling any source files.. And that's likely your real issue.

Add this right after your Glob for sources

for s in sources:
    print("Source:%s"%s)

Run and update your output above.