How to get elements that are out of Parent Class

Question

I am trying to extract some data from the web. However NOT all of the information that I need is in the Parent Class. I can get the information in the Parent class.

QUESTION - Is there a way to get data if it is outside of the parent class? or is there a way to set the below code to extract without using a parent class.

Link

I am using IE as it allos me to search the site. I have tried several code variations however, the extra information is not is the parent class that I am trying to extract from.

I am after the name, location and social media links. Location is at the tops of the webpage out of the class

I tried to use the following for parent class shop-home as all other class fall into it, but it did not work. I have never tried to get data that is not in the parent class so, not 100% sure how to do it. SIM helped with this element.ParentNode.ParentNode.getElementsByClassName as the product url was before the parent. I have been trying to use this for all the other data that is outside the parent, however I can not get it to work. I do not full understand it if someone could explain what the .ParentNode.ParentNode. is doing that will help with my understand and I might be able to work the rest out myself.

The code below is for the first two items that pulls off fine, the code layout is the same for all items except it is as If element.getElementsByClassName("CLASS HERE")(0) . I have tried using ID Tag Span AND SO ON If element.getElementsByClassName("CLASS HERE")(0).getelementsByTagName ("Span") (0)

        Application.ScreenUpdating = False
        Set HTML = objIE.document

''''########## Setting the Parent Class HERE ##########
       Set elements = HTML.getElementsByClassName("v2-listing-card__info") 
         
    ''''Scrolls Down the Browser 
   objIE.document.parentWindow.Scroll 0&, 9999 ' Scrolls Down the Browser
       
    ''''FOR LOOP
        For Each element In elements
''' Element 1
        If element.ParentNode.ParentNode.getElementsByClassName("listing-link")(0) Is Nothing Then 
            wsSheet.Cells(sht.Cells(sht.Rows.Count, "A").End(xlUp).Row + 1, "A").Value = "-" 
        Else
            HtmlText = element.ParentNode.ParentNode.getElementsByClassName("listing-link")(0).href 
            wsSheet.Cells(sht.Cells(sht.Rows.Count, "A").End(xlUp).Row + 1, "A").Value = HtmlText 
        End If
''' Element 2
        If element.getElementsByTagName("h3")(0) Is Nothing Then 
            wsSheet.Cells(sht.Cells(sht.Rows.Count, "B").End(xlUp).Row + 1, "B").Value = "-" 
        Else
            HtmlText = element.getElementsByTagName("h3")(0).innerText ' Get CLASS and Child Nod 'src
            wsSheet.Cells(sht.Cells(sht.Rows.Count, "B").End(xlUp).Row + 1, "B").Value = HtmlText 'return value in column
        End If
''' Element 3

RESULTS - Date in red is wrong or missing as it is not in the above parent class

The shipping in column H pulls off fine as it is in the Parent, If there is no shipping info then a hyphen goes into the cell. Items for C,D,E, are out of the parent class that I am using.


  


  

  
    
      
    
    
      
        
          
        

      
      

      
    
  

  
    

    
      
      
        
          
            
              
              Facebook
            
          
          
            
              
              Instagram
            
          
        
      
    
  

  
    

    
      
        Shop members
      
      
        
          
            
              
                
                  
                
                
                  Lucky Plum Studio
                  Owner

As Always thanks in advance

''######### updated today 22/3/2021 at 6pm uk time #########

In reply to Qharr answer. I had this for location and nothing was collected, could you please explain where i went wrong and I should be able to fix the rest

''' Element 4
DoEvents
          If element.getElementsByClassName("shop-location")(0).getElementsByTagName("Span")(0) Is Nothing Then ' Get CLASS and Child Nod
            wsSheet.Cells(sht.Cells(sht.Rows.Count, "D").End(xlUp).Row + 1, "D").Value = "-" 
        Else
            HtmlText = element.getElementsByClassName("shop-location")(0).getElementsByTagName("Span")(0).innerText 
            wsSheet.Cells(sht.Cells(sht.Rows.Count, "D").End(xlUp).Row + 1, "D").Value = HtmlText 
        End If

QHarr · Accepted Answer

Not sure what to say except read up on html and html document methods/ css selectors so you understand the patterns you need to apply. The rest is just practice and learning which are the fastest and more robust methods.

CSS:

Location: .shop-location span is a span child element with parent having class shop-location
Social media links: #about .text-decoration-none child nodes with one class name that is text-decoration-none, having parent with id about.
Name: [data-region='member-name'] element with data-region attribute having value member-name

Read about css selectors and descendant combinator here

Practice css selectors here

Learn about html here

VBA:

Option Explicit
Public Sub GetInfo()
    Dim ie As SHDocVw.InternetExplorer

    Set ie = New SHDocVw.InternetExplorer

    With ie

        .Visible = True
        .Navigate2 "https://www.etsy.com/uk/shop/LuckyPlumStudio"
        While .Busy Or .readyState <> READYSTATE_COMPLETE: DoEvents: Wend

        With .document
        
            Debug.Print .querySelector(".shop-location span").innerText 'location
            
            Dim i As Long, socialMedias As Object
            
            Set socialMedias = .querySelectorAll("#about .text-decoration-none")
  
            For i = 0 To socialMedias.Length - 1 'media links
                Debug.Print socialMedias.Item(i).href
            Next
            
            Debug.Print .querySelector("[data-region='member-name']").innerText 'company name
            
        End With
        .Quit
    End With

End Sub

Less optimal methods for selecting:

Option Explicit

Public Sub GetInfo()
    Dim ie As SHDocVw.InternetExplorer

    Set ie = New SHDocVw.InternetExplorer

    With ie

        .Visible = True
        .Navigate2 "https://www.etsy.com/uk/shop/LuckyPlumStudio"
        While .Busy Or .readyState <> READYSTATE_COMPLETE: DoEvents: Wend

        With .document
        
            Debug.Print .getElementsByClassName("shop-location wt-display-flex-xs")(0).getElementsByTagName("span")(0).innerText 'location
            
            Dim i As Object, socialMedias As Object
            
            Set socialMedias = .getElementById("about").getElementsByClassName("text-decoration-none clearfix")
  
            For Each i In socialMedias           'media links
                Debug.Print i.href
            Next
            
            Debug.Print .getElementById("about").getElementsByClassName("flag")(0).getElementsByTagName("h6")(0).innerText 'company name
            
        End With
        .Quit
    End With

End Sub

How to get elements that are out of Parent Class

Answers (1)

Related Questions