CODEWITHSUNDEEP
listprologdirected-graph
lolo
lolo

Reputation: 13

Count number of stations directly connected to a given station using prolog(metro stations)

here's the Facts

%first line
connected(new_elmarg,elmarg).
connected(elmarg,ezbet_elnakhl).
connected(ezbet_elnakhl,ain_shams).
connected(ain_shams,elmatareyya).
connected(elmatareyya,helmeyet_elzaitoun).
connected(helmeyet_elzaitoun,hadayeq_elzaitoun).
connected(hadayeq_elzaitoun,saray_elqobba).
connected(saray_elqobba,hammamat_elqobba).
connected(hammamat_elqobba,kobri_elqobba).
connected(kobri_elqobba,manshiet_elsadr).
connected(manshiet_elsadr,eldemerdash).
connected(eldemerdash,ghamra).
connected(ghamra,alshohadaa).
connected(alshohadaa,urabi).
connected(urabi,nasser).
connected(nasser,sadat).
connected(sadat,saad_zaghloul).
connected(saad_zaghloul, alsayyeda_zeinab).
connected(alsayyeda_zeinab,elmalek_elsaleh).
connected(elmalek_elsaleh,margirgis).
connected(margirgis,elzahraa).
connected(elzahraa,dar_elsalam).
connected(dar_elsalam,hadayeq_elmaadi).
connected(hadayeq_elmaadi,maadi).
connected(maadi,thakanat_elmaadi).
connected(thakanat_elmaadi,tora_elbalad).
connected(tora_elbalad,kozzika).
connected(kozzika,tora_elasmant).
connected(tora_elasmant,elmaasara).
connected(elmaasara,hadayeq_helwan).
connected(hadayeq_helwan,wadi_hof).
connected(wadi_hof,helwan_university).
connected(helwan_university,ain_helwan).
connected(ain_helwan,helwan).
%second line
connected(shobra_elkheima,koliet_elzeraa).
connected(koliet_elzeraa,mezallat).
connected(mezallat,khalafawy).
connected(khalafawy,sainte_teresa).
connected(sainte_teresa,road_elfarag).
connected(road_elfarag,massara).
connected(massara,alshohadaa).
connected(alshohadaa,ataba).
connected(ataba,naguib).
connected(naguib,sadat).
connected(sadat,opera).
connected(opera,dokki).
connected(dokki,bohooth).
connected(bohooth,cairo_university).
connected(cairo_university,faisal).
connected(faisal,giza).
connected(giza,omm_elmisryeen).
connected(omm_elmisryeen,sakiat_mekki).
connected(sakiat_mekki,elmounib).

I have to Count number of stations directly connected to a given station without using built in predicate (findall ...).

Input: are_connected(sadat,X).
Output: X = 4.
Input: are_connected(helwan,X).
Output: X = 1.

my code:

are_connected(A,0) :-
        connected(_,A).
are_connected(A,0) :-
        connected(A,_).
are_connected(A,S) :-
    are_connected(A,News),!,
    S is News + 1.

Note:Number of " 0's " are printed should be the output but i don't know how!

Note:in connected(,) the missed atom is underscore(_).

Upvotes: 1

Views: 147

Answers (1)

slago
slago

Reputation: 5509

If you are not allowed to use findall/3, then you can use a dynamic predicate to store the counting:

:- dynamic(myflag/2).

myflag(Name, Old, New) :-
   ( retract(myflag(Name, Old)),
     !
   ; true ),
   Val is New,
   assertz(myflag(Name, Val)).

Example:

?- myflag(counter,_,0), myflag(counter,A,A+1), myflag(counter,B,B+1), myflag(counter,C,C).
A = 0,
B = 1,
C = 2.

Then, using predicate myflag/3, you can define the following predicate:

are_connected(A, N) :-
   myflag(counter, _, 0),          % initialize counter
   (   (   connected(_, A)
       ;   connected(A, _) 
       ),
       myflag(counter, V, V+1),    % increment counter
       fail                        % backtracks to find another solution
   ;   myflag(counter, N, N)       % get final counter value
   ).

Examples:

?- are_connected(sadat, X).
X = 4.

?- are_connected(helwan, X).
X = 1.

In SWI-Prolog, you can use the built-in predicate flag/3, instead of myflag/3.

are_connected(A, N) :-
   flag(counter, _, 0),          % initialize counter
   (   (   connected(_, A)
       ;   connected(A, _) 
       ),
       flag(counter, V, V+1),    % increment counter
       fail                      % backtracks to find another solution
   ;   flag(counter, N, N)       % get final counter value
   ).

Upvotes: 1

Related Questions