CODEWITHSUNDEEP
windowsbatch-file
dij
dij

Reputation: 21

How to batch copy files based on a list (txt) in to another folder with same directory structure?

I have a root directory with over 25,000 files in it. These files are in loads of different subdirectories.

I also have a text file with 4300 lines in it, each line is an absolute path to one of the files in the directory. Like below,

c:\dir1\hat1.gif
c:\dir1\hat2.gif
c:\dir1\dir2\hat1.gif
c:\dir1\dir2\hat2.gif
c:\dir1\dir3\cat.zip
c:\dir1\dir3\banana.exe

I also have another root directory witch is a copy of the original root directory structure but all the directories are empty.

I would like to copy all the files listed in the text file to the directory which is empty and place all the copied files inn the respected subdirectories.

if I use the following batchfile I keep getting file overwrite prompts because it is not copying the files to the correct directories.

@echo off
set dst_folder=c:\DSTN2
for /f "tokens=*" %%i in (USEDFILES.txt) DO (
    xcopy /S/E "%%i" "%dst_folder%"
)

How do I modify this so the files are copied to the correct directory?

Upvotes: 2

Views: 1616

Answers (1)

Squashman
Squashman

Reputation: 14320

Since you are copying specific files from a list, you need to make sure the directory structure exists in the destination if you want it in a similar folder structure. So using the power of the FOR command modifiers you can get the file path only from the file name in the file list. You will use that modifier to create the destination directory and also use it as the destination for the XCOPY command.

I have taken the liberty of providing best practices for all the code you are using.

@echo off

set "dst_folder=c:\DSTN2"
for /f "usebackq delims=" %%G in ("USEDFILES.txt") DO (
    mkdir "%dst_folder%%%~pG" 2>NUL
    xcopy "%%~G" "%dst_folder%%%~pG"
)

Upvotes: 2

Related Questions