CODEWITHSUNDEEP
google-sheetsgoogle-sheets-formularowreversetranspose
user12345
user12345

Reputation: 509

Google Sheet: How to reverse and transpose a row?

Need to reverse and transpose a row in google sheet

enter image description here

like below

enter image description here

Tried below formula but didn't reversed the order. Help me out!

=FILTER(TRANSPOSE(A1:E1),TRANSPOSE(A1:E1)<>"")

Upvotes: 1

Views: 3034

Answers (3)

TheMaster
TheMaster

Reputation: 50697

=SORT(TRANSPOSE(A1:E1),SEQUENCE(COLUMNS(A1:E1)),)
  • SEQUENCE to create a array of sequential numbers
  • SORT to sort them in reverse

If you need to check for blanks, use QUERY to filter:

=QUERY(SORT(TRANSPOSE(A1:E1),SEQUENCE(COLUMNS(A1:E1)),),"where Col1 is not null",0)

Upvotes: 2

Mike Steelson
Mike Steelson

Reputation: 15328

Try

=query(sort(transpose({ARRAYFORMULA(column(A1:E1));A1:E1}),1,false),"select Col2")

enter image description here

Upvotes: 0

player0
player0

Reputation: 1

try:

=QUERY(SORT(FLATTEN(A1:1), FLATTEN(COLUMN(A1:1)), 0),
 "where Col1 is not null")

or:

=INDEX(FLATTEN(VLOOKUP(ROW(A1), {ROW(A1), A1:1}, 
 TRANSPOSE(SORT(SEQUENCE(COUNTA(A1:1))+1, 1, 0)), 0)))

Upvotes: 1

Related Questions