CODEWITHSUNDEEP
terraformterraform-provider-aws
naeroy
naeroy

Reputation: 95

Module for AWS Secret Manager with value/key - Terraform

I have the following TF module to create Secret Manager resources:

resource "aws_secretsmanager_secret" "secrets_manager" {
  count = length(var.secrets)
  name = element(split(":", var.secrets[count.index]),0)
  description = "Managed by Terraform"
}

resource "aws_secretsmanager_secret_version" "secret" {
  count =  length(var.secrets)
  secret_id = aws_secretsmanager_secret.secrets_manager[count.index].id
  secret_string = <<EOF
   {
    "${element(split(":", var.secrets[count.index]),1)}": "${element(split(":", var.secrets[count.index]),2)}"
   }
EOF
}

With:

module "secrets_manager" {
  source = "./modules/secret_manager"
  secrets = [
    "secret_name:secret_value:secret_key",
     ...
    ]
}

This has been working perfectly for me. Now what I want is the possibility without changing this mechanism, to create a Secret without specifying/creating a value/key.

module "secrets_manager" {
  source = "./modules/secret_manager"
  secrets = [
    "secret_name:secret_value:secret_key",
    "secret_name",
    "secret_name:secret_value:secret_key",
     ...
    ]
}

I have been trying using a map as a variable, etc ....no luck:

 secrets_map = {
    secret_one = {
      secret_name = "...."
      secret_value = "...."
      secret_key = "...."
    }

    secret_two = {
      secret_name = "...."
    }
  }
}

Upvotes: 0

Views: 3816

Answers (1)

naeroy
naeroy

Reputation: 95

Working!

resource "aws_secretsmanager_secret" "secrets_manager" {
  for_each    = var.secrets_map
  name        = each.value["secret_name"]
  description = "Managed by Terraform"
}

resource "aws_secretsmanager_secret_version" "secret" {
  for_each = {
    for key, value in var.secrets_map :
    key => value
    if lookup(value, "secret_value", "") != ""
  }
  secret_id     = each.value["secret_name"]
  secret_string = <<EOF
   {
    "${each.value["secret_value"]}": "${each.value["secret_key"]}"
   }
EOF
  depends_on = [
    aws_secretsmanager_secret.secrets_manager
  ]
}

With:

module "secrets_manager" {
  source = "./modules/secret_manager"
  secrets_map = {
    secret_one = {
      secret_name  = "...."
      secret_value = "...."
      secret_key   = "...."
    }
    secret_two = {
      secret_name  = "...."
      secret_value = ""
      secret_key   = ""
    }
  }
}

And:

variable "secrets_map" {
  type = map(object({
    secret_name  = string
    secret_value = string
    secret_key   = string
  }))
}

I couldn't leave the defaults to avoid passing empty values.

Extra:

terraform import .......module.secrets_manager.aws_secretsmanager_secret.secrets_manager[\"secret_two\"] arn....

Thanks to: https://www.youtube.com/watch?v=UFEhJFIj9gY

Upvotes: 1

Related Questions