CODEWITHSUNDEEP
google-sheets
mau
mau

Reputation: 185

Function ARRAY_ROW parameter 2 has mismatched row size. Expected: 1. Actual: 123295

I'm getting the following error with this code. Not sure why is happening since the ranges are actually the same size.

I'm filtering information from another spreadsheet that has over 70k rows and goes from A:AF, which the information updates dynamically with another a script. With that in mind, the formula in this post filters data from that spreadsheet.

UPDATE: After removing the comma and placing ; I got this information. I deleted some rows in the different spreadsheet, but makes no sense since all the ranges are the entire column and not any specific row number.

Function ARRAY_ROW parameter 2 has mismatched row size. Expected: 1. Actual: 123295.

1st try enter image description here 2nd try enter image description here

=sort(FILTER({
IMPORTRANGE(Links!E15,"Audit!A:E"),IMPORTRANGE(Links!E15,"Audit!I:I"),IMPORTRANGE(Links!E15,"Audit!AC:AC"),IMPORTRANGE(Links!E15,"Audit!AE:AE")},

IMPORTRANGE(Links!E15,"Audit!B:B")<>"Time between your actions",

IMPORTRANGE(Links!E15,"Audit!B:B")>=Links!G3,
REGEXMATCH(IMPORTRANGE(Links!E15,"Audit!H:H"),"Start")=FALSE,
REGEXMATCH(IMPORTRANGE(Links!E15,"Audit!H:H"),"End")=FALSE,
REGEXMATCH(IMPORTRANGE(Links!E15,"Audit!I:I"),"End")=FALSE
),1,false)

Error: enter image description here

Upvotes: 0

Views: 597

Answers (1)

player0
player0

Reputation: 1

first, run this fx and allow access:

=IMPORTRANGE(Links!E15, "Audit!A1")

then, try:

=QUERY(IMPORTRANGE(Links!E15, "Audit!A:AE"), 
 "select Col1,Col2,Col3,Col4,Col5,Col9,Col29,Col31 
  where Col2 >= "&Links!G3&"
    and not lower(Col8) matches '.*start.*|.*end.*'
    and not lower(Col9) contains 'end'
  order by Col1 desc")

update 1:

=QUERY({IMPORTRANGE(Links!E15, "Audit!A:E"),
        IMPORTRANGE(Links!E15, "Audit!H:I"),
        IMPORTRANGE(Links!E15, "Audit!AC:AC"),
        IMPORTRANGE(Links!E15, "Audit!AE:AE")}, 
 "select Col1,Col2,Col3,Col4,Col5,Col7,Col8,Col9 
  where Col2 >= "&Links!G3&"
    and not lower(Col6) matches '.*start.*|.*end.*'
    and not lower(Col7) contains 'end'
  order by Col1 desc")

update 2:

=QUERY({IMPORTRANGE(Links!E15, "Audit!A1:AE5000"); 
        IMPORTRANGE(Links!E15, "Audit!A5001:AE10000"); 
        IMPORTRANGE(Links!E15, "Audit!A10001:AE15000"); 
        IMPORTRANGE(Links!E15, "Audit!A15001:AE20000"); 
        IMPORTRANGE(Links!E15, "Audit!A20001:AE25000")}, 
 "select Col1,Col2,Col3,Col4,Col5,Col9,Col29,Col31 
  where Col2 >= "&Links!G3&"
    and not lower(Col8) matches '.*start.*|.*end.*'
    and not lower(Col9) contains 'end'
  order by Col1 desc")

Upvotes: 1

Related Questions