Google Sheets: Average percentage using multiple conditions

Question

I would like to get an average percentage out of my sample, however, I need to use several conditions. I tried to use the AVERAGE and AVERAGEIF together with FILTER but everything returns an error and I think I'm incorrectly "merging" formulas.

You can find my test sheet here.

The rules I need to apply:

1. The score for individual rows is possible to find in the "Data" sheet in cell N and the total results should be visible in the sheet "Calculation" cell E.
2. As the sample is huge in real life, I need to filter out several pieces of information and add conditions:

• to filter out all items where the code/ID starts with 0: Data!A:A&"", "^0.+"
• to filter out all items that are matching the date in the Calculation sheet: Data!C:C=$B3
• to filter all items with the specific name: Data!B:B=$A3

Any idea how to get the average % out of items with specific filters?

---

UPDATE

Expected results: I want to see the total average for a specific date, name, and ID, and let's say I would use these filters, then I would see only the final average percentage.

1. Test =100%
2. Test = 0%
3. Test = 100%

Total Average %: 66.7%

Also, I think the best way would be to use AVERAGEIFS, but I'm getting the error "Array arguments to AVERAGEIFS are of different size".

=AVERAGEIFS(Data!N:N,Data!B:B=$A3,Data!C:C=$B3,Data!A:A&"", "^0.+")

Answer 1

=IFERROR(AVERAGEIFS(Data!N3:N,Data!B3:B,A3,Data!C3:C,B3,ARRAYFORMULA(if(LEN(Data!A3:A),REGEXMATCH(Data!A3:A,"^0.+"),"")),TRUE),"")

or

=IFERROR(AVERAGE(FILTER(Data!N3:N,Data!B3:B=A3,Data!C3:C=B3,REGEXMATCH(Data!A3:A,"^0.+"))),"")

or

=IFERROR(INDEX(QUERY({Data!A3:C,Data!N3:N},"select avg(Col4) where Col1 starts with '0' and Col2 = '"&A3&"' and Col3 = '"&B3&"'"),2,0),"")