Reputation: 31
In KDB, I have a simple table that I am trying to pivot. Using the https://code.kx.com/q/kb/pivoting-tables/ I am still lost. I am a newbie to KDB. I have a table
t:([]sym:`IBM`FB`TESLA`IBM;exchange:`A`A`B`B;OB_p1:4#100.1;OB_p2:100.2 100.2 100.3 100.4;OB_p3:100.5 100.6 100.7 100.8;OB_p4:100.8 100.8 100.8 100.9)
sym exchange OB_p1 OB_p2 OB_p3 OB_p4
IBM A 100.1 100.2 100.5 100.8
FB A 100.1 100.2 100.6 100.8
TESLA B 100.1 100.3 100.7 100.8
IBM B 100.1 100.4 100.8 100.9
I am trying to create the following table:
exchange OB IBM FB TESLA
A OB_1
A OB_1
B OB_1
I was wondering if there is anyone who could kindly assist in this task? I have tried the pivot table recommendation on https://code.kx.com/q/kb/pivoting-tables/ with no luck
Upvotes: 2
Views: 505
Reputation: 13657
Rians answer is a more general approach but this should help you understand the manipulation:
q)ungroup exec((`FB`IBM`TESLA!3#0n),sym!flip(OB_p1;OB_p2;OB_p3;OB_p4))by exchange,OB:count[i]#enlist`OB_p1`OB_p2`OB_p3`OB_p4 from t
exchange OB FB IBM TESLA
--------------------------------
A OB_p1 100.1 100.1
A OB_p2 100.2 100.2
A OB_p3 100.6 100.5
A OB_p4 100.8 100.8
B OB_p1 100.1 100.1
B OB_p2 100.4 100.3
B OB_p3 100.8 100.7
B OB_p4 100.9 100.8
In a functional form it would be:
q)c:cols[t]where cols[t]like"*OB*";
q)s:exec distinct sym from t;
q)ungroup ?[t;();`exchange`OB!(`exchange;(#;(count;`i);enlist enlist c));(,;s!count[s]#0n;(!;`sym;(flip;enlist,c)))]
exchange OB IBM FB TESLA
--------------------------------
A OB_p1 100.1 100.1
A OB_p2 100.2 100.2
A OB_p3 100.5 100.6
A OB_p4 100.8 100.8
B OB_p1 100.1 100.1
B OB_p2 100.4 100.3
B OB_p3 100.8 100.7
B OB_p4 100.9 100.8
Upvotes: 2
Reputation: 3786
Sample table:
t:flip `sym`exchange`OB_p1`OB_p2`OB_p3`OB_p4!flip (
(`IBM;`A;100.1;100.2;100.5;100.8);
(`FB;`A;100.1;100.2;100.6;100.8);
(`TESLA;`B;100.1;100.3;100.7;100.8);
(`IBM;`B;100.1;100.4;100.8;100.9))
Gives:
sym exchange OB_p1 OB_p2 OB_p3 OB_p4
--------------------------------------
IBM A 100.1 100.2 100.5 100.8
FB A 100.1 100.2 100.6 100.8
TESLA B 100.1 100.3 100.7 100.8
IBM B 100.1 100.4 100.8 100.9
unpivot
function taken from https://gist.github.com/rianoc/a14b832f12908c4785e2297995db1e76
unpivot:{[tab;baseCols;pivotCols;kCol;vCol]
base:?[tab;();0b;{x!x}(),baseCols];
newCols:{[k;v;t;p] flip (k;v)!(count[t]#p;t p)}[kCol;vCol;tab] each pivotCols;
baseCols xasc raze {[b;n] b,'n}[base] each newCols
}
Calling:
t:unpivot[t;`sym`exchange;`OB_p1`OB_p2`OB_p3`OB_p4;`OB;`val]
Gives:
sym exchange OB val
--------------------------
FB A OB_p1 100.1
FB A OB_p2 100.2
FB A OB_p3 100.6
FB A OB_p4 100.8
IBM A OB_p1 100.1
IBM A OB_p2 100.2
IBM A OB_p3 100.5
IBM A OB_p4 100.8
IBM B OB_p1 100.1
IBM B OB_p2 100.4
IBM B OB_p3 100.8
IBM B OB_p4 100.9
TESLA B OB_p1 100.1
TESLA B OB_p2 100.3
TESLA B OB_p3 100.7
TESLA B OB_p4 100.8
piv
function taken from https://code.kx.com/q/kb/pivoting-tables/
f
from link simplified for this usecase when naming pivoted columns
piv:{[t;k;p;v;f;g]
v:(),v;
G:group flip k!(t:.Q.v t)k;
F:group flip p!t p;
count[k]!g[k;P;C]xcols 0!key[G]!flip(C:f[v]P:flip value flip key F)!raze
{[i;j;k;x;y]
a:count[x]#x 0N;
a[y]:x y;
b:count[x]#0b;
b[y]:1b;
c:a i;
c[k]:first'[a[j]@'where'[b j]];
c}[I[;0];I J;J:where 1<>count'[I:value G]]/:\:[t v;value F]}
f:{[v;P]P[;0]}
g:{[k;P;c]k,(raze/)flip flip each 5 cut'10 cut raze reverse 10 cut asc c}
Calling:
piv[t;`exchange`OB;(),`sym;(),`val;f;g]
Gives:
exchange OB | FB IBM TESLA
--------------| -----------------
A OB_p1| 100.1 100.1
A OB_p2| 100.2 100.2
A OB_p3| 100.6 100.5
A OB_p4| 100.8 100.8
B OB_p1| 100.1 100.1
B OB_p2| 100.4 100.3
B OB_p3| 100.8 100.7
B OB_p4| 100.9 100.8
Upvotes: 3