CODEWITHSUNDEEP
xpathxsltxslt-2.0xsl-foxpath-2.0
Florian
Florian

Reputation: 388

Why is xsl:value-of behaving completely different depending on the xsl:stylesheet version?

Looking at this XML:

<?xml version="1.0" encoding="UTF-8"?>
<root>
    root
    <child>
        child 1
        <grandchild>
            grandchild 1
        </grandchild>
        <yetanothergrandchild>
            yetanothergrandchild 1
        </yetanothergrandchild>
    </child>
    <child>
        child 2
        <grandchild>
            grandchild 2
        </grandchild>
        <yetanothergrandchild>
            yetanothergrandchild 2
        </yetanothergrandchild>
    </child>
</root>

and that XSL

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:output media-type="text" omit-xml-declaration="yes"/>

    <xsl:template match="/">

        <fo:root>

            <fo:layout-master-set>
                <fo:simple-page-master master-name="simple"
                                       page-height="29.7cm"
                                       page-width="21cm"
                                       margin-top="1cm"
                                       margin-bottom="2cm"
                                       margin-left="2.5cm"
                                       margin-right="2.5cm">
                    <fo:region-body margin-top="3cm"/>
                    <fo:region-before extent="3cm"/>
                    <fo:region-after extent="1.5cm"/>
                </fo:simple-page-master>
            </fo:layout-master-set>

            <fo:page-sequence master-reference="simple">
                <fo:flow flow-name="xsl-region-body">

                    <fo:block font-size="12pt"
                              font-family="sans-serif"
                              line-height="15pt"
                              space-after.optimum="3pt"
                              text-align="justify">
                        <xsl:value-of select="root/child/grandchild"/>
                        <xsl:value-of select="root/child/yetanothergrandchild"/>
                    </fo:block>

                </fo:flow>
            </fo:page-sequence>
        </fo:root>
    </xsl:template>
</xsl:stylesheet>

If I put the xsl:stylesheet version to 1.0, the output is: grandchild 1 yetanothergrandchild 1

If I put it to 2.0, the output is: grandchild 1 grandchild 2 yetanothergrandchild 1 yetanothergrandchild 2

Of course, I read already through various lists of differences in between XSL T 1 and 2 but I cannot find any hint of a change which could cause that.

Can somebody tell me how and why that behaves that differently?

Upvotes: 0

Views: 91

Answers (2)

Martin Honnen
Martin Honnen

Reputation: 167696

See https://www.w3.org/TR/xslt20/#backwards and then https://www.w3.org/TR/xslt20/#incompatibilities saying

J.1.3 Backwards Compatibility Behavior Some XSLT constructs behave differently under XSLT 2.0 depending on whether backwards compatible behavior is enabled. In these cases, the behavior may be made compatible with XSLT 1.0 by ensuring that backwards compatible behavior is enabled (which is done using the [xsl:]version attribute).

These constructs are as follows:

If the xsl:value-of instruction has no separator attribute, and the value of the select expression is a sequence of more than one item, then under XSLT 2.0 all items in the sequence will be output, space separated, while in XSLT 1.0, all items after the first will be discarded.

...

Upvotes: 1

michael.hor257k
michael.hor257k

Reputation: 117083

In XSLT 1.0 the xsl:value-of instruction returns the string-value of the first node in the selected node-set.

In XSLT 2.0 the instruction returns the value of every node in the selected sequence, separated by a space or by the string specified in the separator attribute.

These are my formulations, the specs are more difficult to follow.

Upvotes: 1

Related Questions