CODEWITHSUNDEEP
perl
thebourneid
thebourneid

Reputation: 67

How to rename directories recursively

I want to rename directories recursively using File::Find::Rule, eg. remove extra spaces in each found but as I understand the module doesn't do finddepth and renames only one. Is there a way to do that. Thanks.

use autodie;
use strict ;
use warnings;
use File::Find::Rule;

my $dir = 'D:/Test';

my @fd = File::Find::Rule->directory
->in( $dir );

for my $fd ( @fd ) {
    my $new = $fd;

    $new =~ s/\s\s+/ /g;

    print "$new\n";

    rename $fd, $new;   
}

Upvotes: 0

Views: 3397

Answers (2)

Joel Berger
Joel Berger

Reputation: 20280

I have a module for doing actions recursively in a directory tree. It didn't have the ability to act on the directories themselves though, so it took a little updating. I have uploaded version 0.03 of my File::chdir::WalkDir, but until it shows up, it can be installed from its GitHub repo, and now available using your fav CPAN utility. This script would then remove spaces from directory names inside the base directory 'Test' relative to the working directory:

#!/usr/bin/env perl

use strict;
use warnings;

use File::chdir::WalkDir 0.030;
use File::Copy;

my $job = sub {
  my ($name, $in_dir) = @_;

  #ONLY act on directories
  return 0 unless (-d $name);

  my $new_name = $name;
  if ($new_name =~ s/\s+/ /g) {
    move($name, $new_name); 
  }

};

walkdir( 'Test', $job, {'act_on_directories' => 1} );

Upvotes: 0

ikegami
ikegami

Reputation: 385789

You want to process the deeper results first, so process the list in reverse. You can only rename the leaf part of the path; you'll get to the more shallow parts later.

use Path::Class qw( dir );

for ( reverse @fd ) {
   my $dir = dir($_);
   my $parent = $dir->parent;
   my $old_leaf = my $new_leaf = $dir->dir_list(-1);

   $new_leaf =~ s/\s+/ /g;

   if ($new_leaf ne $old_leaf) {
      my $old_file = $parent->dir($old_leaf);
      my $new_file = $parent->dir($new_leaf);

      # Prevent accidental deletion of files.
      if (-e $new_file) {
         warn("$new_file already exists\n");
         next;
      }

      rename($old_file, $new_file);
   }
}

Answer to original question:

I don't see how FFR comes into play.

rename 'Test1/Test2/Test3', 'Test1/Test2/Dir3';
rename 'Test1/Test2', 'Test1/Dir2';
rename 'Test1', 'Dir1';

For arbitrary paths,

use Path::Class qw( dir );

my @parts1 = dir('Test1/Test2/Test3')->dir_list();
my @parts2 = dir('Dir1/Dir2/Dir3'   )->dir_list();

die if @parts1 != @parts2;

for (reverse 0..$#parts1) {
   my $path1 = dir(@parts1[ 0..$_ ]);
   my $path2 = dir(@parts2[ 0..$_ ]);
   rename($path1, $path2);
}

Or maybe you want to rename all Test1 to Dir1, Test2 to Dir2, and Test3 to Dir3, process the list in reverse order.

my %map = (
   'Test1' => 'Dir1',
   'Test2' => 'Dir2',
   'Test3' => 'Dir3',
);

my $pat = join '|', map quotemeta, keys %map;

for ( reverse @fd ) {
   my $o = $_;
   my $n = $_;
   $n =~ s{/\K($pat)\z}{$map{$1}};
   if ($n ne $o) {
      if (-e $n) {
         warn("$n already exists\n");
         next;
      }

      rename($o, $n);
   }
}

Upvotes: 3

Related Questions