CODEWITHSUNDEEP
autohotkey
protter
protter

Reputation: 131

Autohotkey Hotstring is too slow

If I insert the Hotstring into another program it is not fast enough and mixes sometimes keys on the right position or it lags. It happens when I am using a long text.

I am using:

:*:ex1::Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod t
        empor incididunt ut labore et dolore magna aliqua. Ut enim ad minim venia
        m, quis nostrud exercitation ullamco laboris nisi ut aliquip ex ea commod
        o consequat. Duis aute irure dolor in reprehenderit in voluptate velit es
        se cillum dolore eu fugiat nulla pariatur. Excepteur sint occaecat cupida
        tat non proident, sunt in culpa qui officia deserunt mollit anim id est l
        aborum Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod t
        empor incididunt ut labore et dolore magna aliqua. Ut enim ad minim venia
        m, quis nostrud exercitation ullamco laboris nisi ut aliquip ex ea commod
        o consequat. Duis aute irure dolor in reprehenderit in voluptate velit es
        se cillum dolore eu fugiat nulla pariatur. Excepteur sint occaecat cupida
        tat non proident, sunt in culpa qui officia deserunt mollit anim id est l
        aborum

And it will result in some errors or a longer waiting duration.

This works faster, but sometimes I get an error with double text if I press an Endchar like enter too fast, or I do some different things which I can't lay my finger on.

:*:ex2::  
Clipboard = %text%
Send ^v
Exit

Also there is the Clipboard messed up (I think I can store it with an variable and refill it but I am using this Multi-clipboard from windows Windows+V)

Also I am updating the Autohotkey script with excel and it is much easier to use concatenate with the first example.

=IF(List1!B34<>"",(CONCATENATE(":",List1!C34,":",List1!A34,"::",List1!B34)),(CONCATENATE(";",List1!A34)))

So I can use in C something like *0 In A the shortcut and in B the actual text. If there is nothing in the shortcut field, my headline is inserted in the code for a better overview.

Thanks

Upvotes: 0

Views: 233

Answers (1)

Relax
Relax

Reputation: 10543

Try this

:*:ex1::                    
ClipSaved := ClipboardAll  ; save the entire clipboard to the variable ClipSaved
clipboard := ""            ; empty the clipboard (start off empty to allow ClipWait to detect when the text has arrived)
clipboard =                ; copy this text:
(
Lorem ipsum dolor sit amet, consectetuer adipiscing elit, sed diam nonummy nibh euismod tincidunt ut laoreet dolore magna aliquam erat volutpat. 
Ut wisi enim ad minim veniam, quis nostrud exerci tation ullamcorper suscipit lobortis nisl ut aliquip ex ea commodo consequat. 
Duis autem vel eum iriure dolor in hendrerit in vulputate velit esse molestie consequat, vel illum dolore eu feugiat nulla facilisis at vero et accumsan et iusto odio dignissim qui blandit praesent luptatum zzril delenit augue duis dolore te feugait nulla facilisi. 
Lorem ipsum dolor sit amet, consectetuer adipiscing elit, sed diam nonummy nibh euismod tincidunt ut laoreet dolore magna aliquam erat volutpat. 
Ut wisi enim ad minim veniam, quis nostrud exerci tation ullamcorper suscipit lobortis nisl ut aliquip ex ea commodo consequat. 
Duis autem vel eum iriure dolor in hendrerit in vulputate velit esse molestie consequat, vel illum dolore eu feugiat nulla facilisis at vero et accumsan et iusto odio dignissim qui blandit praesent luptatum zzril delenit augue duis dolore te feugait nulla facilisi. 
Nam liber tempor cum soluta nobis eleifend option congue nihil imperdiet doming id quod mazim placerat facer possim assum.
)
ClipWait, 1                   ; wait for the clipboard to contain data. 
If (!ErrorLevel)              ; If NOT ErrorLevel clipwait found data on the clipboard
    Send, ^v                  ; paste the text
Sleep, 300                    ; don't change clipboard while pasting! (Sleep > 0)
clipboard := ClipSaved        ; restore original clipboard
VarSetCapacity(ClipSaved, 0)  ; free the memory
return

If you often have to send such a complex or long text, you can create a function, for not repeating the whole code every time:

:*:ex1:: 
my_text =
(
Lorem ipsum dolor sit amet, consectetuer adipiscing elit, sed diam nonummy nibh euismod tincidunt ut laoreet dolore magna aliquam erat volutpat. 
Ut wisi enim ad minim veniam, quis nostrud exerci tation ullamcorper suscipit lobortis nisl ut aliquip ex ea commodo consequat. 
Duis autem vel eum iriure dolor in hendrerit in vulputate velit esse molestie consequat, vel illum dolore eu feugiat nulla facilisis at vero et accumsan et iusto odio dignissim qui blandit praesent luptatum zzril delenit augue duis dolore te feugait nulla facilisi. 
Lorem ipsum dolor sit amet, consectetuer adipiscing elit, sed diam nonummy nibh euismod tincidunt ut laoreet dolore magna aliquam erat volutpat. 
Ut wisi enim ad minim veniam, quis nostrud exerci tation ullamcorper suscipit lobortis nisl ut aliquip ex ea commodo consequat. 
Duis autem vel eum iriure dolor in hendrerit in vulputate velit esse molestie consequat, vel illum dolore eu feugiat nulla facilisis at vero et accumsan et iusto odio dignissim qui blandit praesent luptatum zzril delenit augue duis dolore te feugait nulla facilisi. 
Nam liber tempor cum soluta nobis eleifend option congue nihil imperdiet doming id quod mazim placerat facer possim assum.
)
Send(my_text)
return

Send(text){
    ClipSaved := ClipboardAll
    clipboard := ""
    clipboard := text
    ClipWait, 1
    If (!ErrorLevel)
        Send, ^v        
    Sleep, 300
    clipboard := ClipSaved
    VarSetCapacity(ClipSaved, 0)
}

See ClipboardAll and ClipWait

Upvotes: 2

Related Questions