CODEWITHSUNDEEP
csh
twimo
twimo

Reputation: 4217

How do I split a String in CSH?

For example, I want to split "one,two,three" with comma as delimiter and use a loop to process the resulted three substring separately.

Upvotes: 12

Views: 51902

Answers (3)

Kevin
Kevin

Reputation: 86

set list = one,two,three
foreach i ( $list:as/,/ / )
  echo $i
end

Upvotes: 3

reflux
reflux

Reputation: 141

A simpler solution than the current one presented involves using the built-in substitution modifer -- there is no need or reason to wastefully use a loop or external command substitution in this instance:

set list = one,two,three
set split = ($list:as/,/ /)

echo $split[2] # returns two

() creates a list, the :s is the substitution modifier and :as repeats the subtitution as many times as needed.

Furthermore, t/csh does not require quoting of bare strings, nor variables that do not require forced evaluation.

Upvotes: 14

Keith Thompson
Keith Thompson

Reputation: 263537

For example:

set s = "one,two,three"
set words = `echo $s:q | sed 's/,/ /g'`
foreach word ($words:q)
    echo $word:q
end

But consider whether csh is the right tool for whatever job you're doing:

http://www.bmsc.washington.edu/people/merritt/text/cshbad.txt

Upvotes: 9

Related Questions