CODEWITHSUNDEEP
glslwebgl
tinoliam
tinoliam

Reputation: 11

textureSize returns a vec2 but the compiler tells me it is not a vec2

I got this biqubic shader from this post, but it won't run in my glsl code becuase of a vec2 misrecognision issue I can't found the answer

Error compiling FRAGMENT_SHADER: ERROR: 0:44: '=' : cannot convert from 'highp 2-component vector of int' to 'highp 2-component vector of float'

// from http://www.java-gaming.org/index.php?topic=35123.0
vec4 cubic(float v){
    vec4 n = vec4(1.0, 2.0, 3.0, 4.0) - v;
    vec4 s = n * n * n;
    float x = s.x;
    float y = s.y - 4.0 * s.x;
    float z = s.z - 4.0 * s.y + 6.0 * s.x;
    float w = 6.0 - x - y - z;
    return vec4(x, y, z, w) * (1.0/6.0);
}

vec4 textureBicubic(sampler2D sampler, vec2 texCoords){
   /// next line is there the issue is
   vec2 texSize = textureSize(sampler, vec2(0.0, 0.0)).rg;
   
   vec2 invTexSize = 1.0 / texSize;
      
   texCoords = texCoords * texSize - 0.5;
      
   vec2 fxy = fract(texCoords);
   texCoords -= fxy;

   vec4 xcubic = cubic(fxy.x);
   vec4 ycubic = cubic(fxy.y);

   vec4 c = texCoords.xxyy + vec2 (-0.5, +1.5).xyxy;
    
   vec4 s = vec4(xcubic.xz + xcubic.yw, ycubic.xz + ycubic.yw);
   vec4 offset = c + vec4 (xcubic.yw, ycubic.yw) / s;
    
   offset *= invTexSize.xxyy;
    
   vec4 sample0 = texture(sampler, offset.xz);
   vec4 sample1 = texture(sampler, offset.yz);
   vec4 sample2 = texture(sampler, offset.xw);
   vec4 sample3 = texture(sampler, offset.yw);

   float sx = s.x / (s.x + s.y);
   float sy = s.z / (s.z + s.w);

   return mix(
      mix(sample3, sample2, sx), mix(sample1, sample0, sx)
   , sy);
}

the original post : Efficient Bicubic filtering code in GLSL?

to get the xy component from a texture textureSize(sampler, vec2(0.0, 0.0)).rg;

Upvotes: 1

Views: 111

Answers (1)

Mugen87
Mugen87

Reputation: 31086

The return value of textureSize() is ivec2 when using the function with a sampler2D. Also the parameterization isn't right (lod is an integer value). It should be:

ivec2 texSize = textureSize(sampler, 0);

If you need a float vector, do this:

vec2 texSize = vec2(textureSize(sampler, 0));

Upvotes: 0

Related Questions