In Emacs, how to prevent org-babel-detangle from changing my frame/window/buffer configuration?

Question

What I want:

• I run org-babel-detangle, and nothing changes in the current frame/window/buffer configuration, focus stays the same

What happens:

• As you can see on screenshots, a new buffer (with the originating .org file) is added to the current tab-line, and also to a new frame, which becomes focused

What I've tried:

• Suppressing display-buffer using display-buffer-alist '((".*" (display-buffer-no-window))). Has no effect, maybe I'm not doing it right?
• Saving excursions. It kind of works, but still leaves a mess - 1 new buffer and 1 new frame.

(defmacro save-frame-excursion (&rest body)
   "Eval BODY and return to the currently selected frame."
   (let ((frame-var (gensym "FRAME")))
     `(let ((,frame-var (selected-frame)))
        (unwind-protect
            (progn ,@body)
          (select-frame-set-input-focus ,frame-var)))))

(defun org-babel-detangle-no-buffer-pop-up (orig-fun &rest args)
  (save-window-excursion
    (save-frame-excursion
     (apply orig-fun args))))
(advice-add 'org-babel-detangle :around #'org-babel-detangle-no-buffer-pop-up)

Answer 1

Found a solution. Turns out, display-buffer-alist '((".*" (display-buffer-no-window))) doesn't work without an additional argument - (allow-no-window . t). This was very contrintuitive, and that threw me off.

Full working solution below:

(defun org-babel-detangle-no-buffer-pop-up (orig-fun &rest args)
  (save-excursion
    (let ((display-buffer-alist
           '((".*" (display-buffer-no-window) (allow-no-window . t)))))
      (apply orig-fun args))))

(advice-add 'org-babel-detangle :around #'org-babel-detangle-no-buffer-pop-up)