Tabstrip not showing in selection screen

Question

I want to set two tabs.

When I run the program, it only shows the address tab and the tab strip control to switch to the other tab doesn't show up. Why?

I defined the two subscreens as follows:

REPORT ZZ_2003_CUST.
TABLES SSCRFIELDS.

DATA: WA_CUST        TYPE SCUSTOM,
      WA_CUST_NAME   TYPE SCUSTOM-NAME,
      WA_CUST_STREET TYPE SCUSTOM-STREET.

"Tabstrips
SELECTION-SCREEN BEGIN OF TABBED BLOCK TABBLOCK FOR 10 LINES.
SELECTION-SCREEN:  TAB (20) ADDR_TAB USER-COMMAND ADDR_TAB DEFAULT SCREEN 800,
                   TAB (20) BUS_TAB USER-COMMAND BUS_TAB DEFAULT SCREEN 100.
SELECTION-SCREEN END OF BLOCK TABBLOCK.

"Address Data Tab
SELECTION-SCREEN BEGIN OF SCREEN 800 AS SUBSCREEN.
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE text-010.
SELECT-OPTIONS: CST_NAME FOR WA_CUST_NAME,
                CST_STRT FOR WA_CUST_STREET.
PARAMETERS: CST_PSTC TYPE SCUSTOM-POSTCODE,
            CST_CITY TYPE SCUSTOM-CITY.
SELECTION-SCREEN END OF BLOCK b1.
SELECTION-SCREEN END OF SCREEN 800.

"Business Data Tab
SELECTION-SCREEN BEGIN OF SCREEN 100 as SUBSCREEN.
SELECTION-SCREEN BEGIN OF BLOCK b2 WITH FRAME TITLE text-020.
PARAMETERS: DISCOUNT RADIOBUTTON GROUP BSDT,
            CUS_TYPE RADIOBUTTON GROUP BSDT.
SELECTION-SCREEN END OF BLOCK b2.
SELECTION-SCREEN END OF SCREEN 100.

Answer 1

The solution is to add an initialisation of the two tab names like:

INITIALIZATION.
  ADDR_TAB = 'Address'.
  BUS_TAB = 'Business Data'.

This will make the tab visible after displaying the screen.